function []=marche(n,p)//trace une marche de la ruine du joueur issue de 0
    clf()
    V=rand(1,n);=
    U=bool2s(V<p);//Je crée le vecteur (U1,...,Un) en comparant un vecteur de variable uniforme sur [0,1] avec p, j'obtiens le vecteur (X1,...,Xn) en faisant 2+U-1
    S=cumsum(2*U-1);//j'utilise cumsum pour avoir le vecteur (S1,...Sn)
    plot2d([1:n],S)
endfunction


function [S]=sortie1(k,m,p)//calcule l'endroit où on sort
    //Le principe est le suivant: je pars de k, comme je me déplace de 1 en 1, à chaque moment, je regarde où je suis, si je ne suis ni en 0 ni en m alors je me déplace une fois, sinon je sors de ma boucle et je rend l'endroit où je suis sortie
   
    S=k;
    n=0;
    while (S>0)&(S<m)
        n=n+1;
        S=S+(2*bool2s(rand(1,1)<p)-1);
    end
endfunction

function [n]=sortie2(k,m,p)//calcul le temps de sortie
    //Le programme est le même que sortie1, mais cette fois-ci je m'interesse au nombre d'étapes avant de sortir
    S=k;
    n=0;
    while (S>0)&(S<m)
        n=n+1;
        S=S+(2*bool2s(rand(1,1)<p)-1);
    end
endfunction


function []=proba(k,m,p,n)
clf()
    P=[]
    //Je crée un vecteur P contenant n réalisation du lieu de sortie
    for i=1:n
        P=[P;sortie1(k,m,p)]
    end
    P=bool2s(P==0) //Je regarde quand je suis sortie en 0 et je fais la somme pour avoir le nombre de sortie en 0
   plot2d([1:n],cumsum(P')./[1:n])//Je trace pour chaque n (nombre de réalisation) la moyenne de sortie en 0 qui correspond
   if p==1/2 then
       plot2d([1:n],(1-k/m)*ones(1,n)) 
   else
       a=(1-p)/p;
       b=(1-a^k)/(1-a^m)
       plot2d([1:n],(1-b)*ones(1,n))
    end
    //Je compare sur le dessin avec la valeur que je dois obtenir.
    // Vous auriez aussi pu juste faire la moyenne pour n assez grand et comparer avec la valeur théorique
endfunction


function []=temps(k,m,p,n)
    clf()
    //Je crée un vecteur contenant n réalisations du temps de sortie
    a=[]
    for i=1:n
        a=[a,sortie2(k,m,p)]
    end
    plot2d([1:n],cumsum(a)./[1:n])
   if p==1/2 then
       plot2d([1:n],k*(m-k)*ones(1,n)) 
   else
       a=(1-p)/p;
       b=(1-a^k)/(1-a^m)
       plot2d([1:n],m/(2*p-1)*(b-k/m)*ones(1,n))
    end
endfunction