**AUTEUR : Isabelle CADORET-DAVID**

CALENDAR 1992 10 12
ALLOCATE 1994:6
OPEN DATA bresil.wks
DATA(FORMAT=wks,ORG=obs) /
*PRINT /

DISPL '***Modèle d"hyperinflation - évaluation avec des données sur le Brésil***'


*calcul du taux d'inflation mensuel*
SET pi = LOG(ipc)-LOG(ipc{1})

*calcul du logarithme de M/P*
SET logmp = LOG(md/ipc)

/*
**estimation du modèle d'hyperinflation avec l'hypothèse d'anticipation
adaptatives****
*/

DISP '*estimation avec la méthode des MCO (hypothèse d"anticipation adaptative)*'

LINREG logmp  / resids
# CONSTANT pi logmp{1}
set res = resids
set res1 = res{1}

*détection d"un problème d"autocorrélation avec le graphique des résidus*
SCAT(STYLE=SYMBOL) 1
# res res1
GRAPH 1
# res

*calcul de la matrice de variance covariance des paramètres estimés*
COMPUTE varb = %SEESQ*%XX
WRITE 'matrice de variance-covariance des paramètres' varb

*calcul de la statistique h de Durbin*

COMPUTE denom = 1 - %nobs*varb(3,3)
IF denom>0
COMPUTE h = (1-(%durbin/2))*sqrt(%nobs/denom)
Else
COMPUTE h = 0.0
DISP 'Statistique h de durbin' h
CDF NORMAL h
END IF

*calcul de l'effet à long terme du taux d'inflation*
COMPUTE mlt = %beta(2)/(1-%beta(3))
DISP 'multiplicateur de long terme' mlt


/*
**estimation du modèle d'hyperinflation avec l'hypothèse d'anticipation
rationelles****
*/

SET logm = LOG(md)
SET logipc = LOG(ipc)
SET logmp1 = logmp{1}


DISP '*estimation avec la méthode des VI (hypothèse d"anticipation rationnelle)*'
INST CONSTANT logm{2} logipc{2}
LINREG(INST) logmp1
# CONSTANT pi

*on obtient le même résultat en procédant de la manière suivante:*
*on estime la variable dipc en fonction des instruments (logm{2} logipc{2})*
*puis on utilise comme variable instrumentable la valeur estimée de dipc*


LINREG pi
# CONSTANT logm{2} logipc{2}
PRJ VI
INST CONSTANT vi
LINREG(INST) logmp1
# CONSTANT pi

*remarque: on obtient les mêmes coefficients lorqu'on estime avec la *
*méthode des MCO le modèle suivant.**

LINREG logmp1
# CONSTANT vi

/*
***Cependant les écart-types estimés ne sont correctement calculés car on utilise dans
ce calcul un estimateur de la variance des aléas égale à la somme des carrés des résidus
divisée par le nombre d'observations moins le nombre de paramètres à estimés. On doit
utiliser la somme des carrés des résidus divisée par le nombre d'observations.***
***De même, la somme des carrés des résidus n'est pas identique car dans un cas on calcule
cette somme en prenant la variable explicative dipc et dans l'autre cas en prenant la
variable explicative vi. ***
***Il faut donc utiliser la commande INST pour obtenir les bons résultats****
*/