**AUTEUR : Isabelle CADORET-DAVID**

DISP '***************************************************************************'
DISP '***PARTIE 1 - estimation avec la méthode de Zellner************************'
DISP '***************************************************************************'

CALENDAR 1935 1 1
ALLOCATE 1954:1
OPEN DATA SURFIRME.WKS
data(format=wks,org=obs) / date GMI GMF GMC CHRI CHRF CHRC GEI GEF GEC $
WESTI WESTF WESTC USI USF USC
**Print / GMI GMF USF USC

EQUATION GMEQ GMI
# CONSTANT GMF GMC

EQUATION CHREQ CHRI
# CONSTANT CHRF CHRC

EQUATION GEEQ GEI
# CONSTANT GEF GEC

EQUATION WESTEQ WESTI
# CONSTANT WESTF WESTC

EQUATION USEQ USI
# CONSTANT USF USC

DISP 'estimation avec les MCO pour l"entreprise GM'
LINREG(EQUATION=GMEQ) GMI
LINREG(EQUATION=CHREQ) CHRI
LINREG(EQUATION=GEEQ) GEI
LINREG(EQUATION=WESTEQ) WESTI
LINREG(EQUATION=USEQ) USI


DISP 'estimation avec la méthode de Zellner'
SUR 5
#GMEQ
#CHREQ
#GEEQ
#WESTEQ
#USEQ


DISP 'estimation avec la méthode de Zellner itérative'
SUR(iters=200) 5
#GMEQ      RESGM
#CHREQ     RESCHR
#GEEQ      RESGE
#WESTEQ    RESWEST
#USEQ      RESUS

END 1

DISP '***************************************************************************'
DISP '***PARTIE 2 - estimation panel************************'
DISP '***************************************************************************'

DISP '***************************************************************************'
DISP '**estimation avec les données empilées, en panel **'

CALENDAR(PANELOBS=20) 1935
ALLOCATE 0 5//1954:1
OPEN DATA panelfirme.wks
DATA(FORMAT=wks,ORG=obs) / date Invest FMV CS CODE
*PRINT / invest fmv cs code
COMPUTE nindiv=5
COMPUTE tperiod=20

DISP '** hypothese de parametres identiques pour tous les individus **'
DISP '** et test d"hétéroscédasticité avec le test du ratio de vraisemblance (test d"une variance spécifique à chaque individu)**'

LINREG invest / resids_MCO
# CONSTANT FMV CS

COMPUTE sig = %rss/100
DISP 'sig' sig

* calcul de la variance des résidus par entreprise *
*on peut alors utiliser la série pour corriger de l'hétéroscédasticité*
PANEL(SPREAD=vares) resids_mco
DO i=1,nindiv
PRINT i//1935:01 i//1935:01 vares
END DO I

*calcul du ratio de vraisemblance*
COMPUTE LR = (100 * log(sig)) - 20 * ( log(vares(1//1935:01)) + $
	log(vares(2//1935:01)) + log(vares(3//1935:01)) + $
	log(vares(4//1935:01)) + log(vares(5//1935:01)) )
CDF CHISQUARED LR 4

*la commande PSTAT(SPREAD) permet de faire le même calcul*
PSTATS(SPREAD) resids_mco

*estimation par MCG*
LINREG(SPREAD=vares) invest / resids_MCG
# CONSTANT FMV CS

* calcul de la variance des résidus par entreprise avec l'estimation MCG *
PANEL(SPREAD=varmcgi) resids_mcg
DO i=1,5
PRINT i//1935:01 i//1935:01 varmcgi
END DO I


DISP '***************************************************************************'
DISP '** estimation avec des coefficients aléatoires **'
DEC VECT[symm] xxmats(nindiv)
dec vect[vect] betas(nindiv)
DEC VECT       sigmas(nindiv)
DEC SYMM delta(3,3)
DEC SYMM xxgls(3,3)
DEC VECT betagls(3)
DEC INTEGER k

*estimation par individu avec les mco *
*et sauvegarde de %xx, %beta* et %seesq , accumuler la somme des coefficients et produits croisé*
COMPUTE delta=%const(0.0)
COMPUTE betagls=%const(0.0)
DO i=1,nindiv
  LINREG(NOPRINT) invest i//1 i//20
   # CONSTANT FMV CS
   COMPUTE xxmats(i)=%xx
   COMPUTE betas(i)=%beta
   COMPUTE sigmas(i)=%seesq
   EWISE delta(j,k)=delta(j,k)+%beta(j)*%beta(k)
   COMPUTE betagls=betagls+%beta
END DO i

* Estimation de la matrice de covariance des vecteurs beta*
EWISE delta(j,k)=1.0/(nindiv-1)*(delta(j,k)-(1.0/nindiv)*betagls(j)*betagls(k))

*Calcul de la matrice de covariance pour appliquer les MCG*
COMPUTE xxgls=%const(0.0)
DO i=1,nindiv
   COMPUTE xxmats(i)=inv(delta+sigmas(i)*xxmats(i))
   COMPUTE xxgls=xxgls+xxmats(i)
END DO I
COMPUTE xxgls=inv(xxgls)

*Calcul des coefficients*
COMPUTE betagls=%const(0.0)
DO i=1,nindiv
   compute betagls=betagls+xxgls*xxmats(i)*betas(i)
END DO i
LINREG(CREATE,COEFFS=betagls,COVMAT=xxgls,NOSCALE) invest
# CONSTANT FMV CS