**AUTEUR : Isabelle CADORET-DAVID**


CALENDAR 1960 1 1
ALLOCATE 1995:1
OPEN DATA essencerats.xls
DISPLAY '*ouverture du fichier*'

DATA(FORMAT=xls,ORG=obs) /

PRINT /
DISPLAY '*impression de toutes les séries du fichier'


DISPLAY '******************************************************************************'
DISPLAY '*Transformation des données en logarithme*'
SET gpop = g/pop
LOG gpop / lgpop
LOG y / ly
LOG pnc / lpnc
LOG puc / lpuc
LOG pg / lpg


SCAT(STYLE=SYMBOL) 1
# lgpop ly
*graphique de lgpop en fonction de ly*
*lorsqu'on regarde l'évolution on observe un problème de changement structurel*

DISPLAY '******************************************************************************'

DISPLAY 'Estimation du modèle de régression simple et des modèles de régression multiple'
LINREG lgpop
# CONSTANT ly
*estimation du modèle avec les mco  , le coefficient de détermination est égal à 0,80 donc 80% de la variance*
*totale est expliquée par le modèle*
*l'écart-type estimé des aléas est égal à 0,068 = somme des carrés des résidus (0,158)/ (nombre d'observations - nombres de paramètres (34))
*le F(1,34) correspoond à la statistique de Fisher du test de significativité globale de la régression, en dessous est donné le niveau de *
*significativité du test, il est inférieur à 5% donc on refuse l'hypothèse nulle
*Std error = l'écart-type estimé des paramètres, le T-sat est le rapport entre coeff et Std Error, Signif donne le niveau de significativité *
*du test de Student de significativité des paramètres, Signif est à chaque fois inférieur à 5% donc on refuse l'hypothèse nulle*

LINREG lgpop
# CONSTANT ly lpg

LINREG lgpop
# CONSTANT ly lpg lpnc

LINREG lgpop
# CONSTANT ly lpg lpnc lpuc


DISPLAY '******************************************************************************'

DISPLAY 'Corrélation simple des variables explicatives avec la variable lgpop'
COMPUTE cory = %CORR(lgpop,ly)
DISP 'Correlation avec ly' cory
COMPUTE corpg = %CORR(lgpop,lpg)
DISP 'Correlation avec lpg' corpg
COMPUTE corpnc = %CORR(lgpop,lpnc)
DISP 'Correlation avec logpnc' corpnc
COMPUTE corpuc = %CORR(lgpop,lpuc)
DISP 'Correlation avec lpuc' corpuc


DISPLAY '******************************************************************************'

DISPLAY 'Corrélation partielle de la variable ly avec la variable lgpop'
LINREG lgpop   / res1
# CONSTANT lpg lpnc lpuc
LINREG ly   / res2
# CONSTANT lpg lpnc lpuc
LINREG RES1
#  res2
DISPLAY '*le coefficient de corrélation partiel est donné par la racine carré du coefficient de détermination '
DISPLAY 'de la régression précédente*'
COMPUTE corrp = sqrt(%RSQUARED)
DISP 'Correlation partielle avec ly' corrp


DISPLAY '******************************************************************************'

DISPLAY 'Test de contraintes linéaires'
LINREG(noprint) lgpop
# CONSTANT ly lpg lpnc lpuc
RESTRICT(CREATE) 2  ; *permet de tester si les coefficients de lpnc et de lpuc sont nuls*
# 4
# 1 0
# 5
# 1 0

**autre manière de programmer le test de contrainte quand il s'agit de contraintes d'exclusion**
LINREG(noprint) lgpop
# CONSTANT ly lpg lpnc lpuc
EXCLUDE
# lpnc lpuc

DISPLAY '******************************************************************************'

DISPLAY 'Test de stabilité de Chow'

DISP '1) estimation du modèle sans contrainte, paramètres différents sur les 2 sous-périodes'
LINREG lgpop 1960:1 1975:1 ;*estimation sur la première sous-période*
# CONSTANT ly lpg lpnc
COMPUTE res0 = %RSS ; *on réserve la somme des carrés des résidus de la régression*
COMPUTE ndf0 = %NDF ; **on réserve le degré de liberté*


LINREG lgpop 1976:1 1995:1
# CONSTANT ly lpg lpnc
COMPUTE res00 = %RSS
COMPUTE ndf00 = %NDF

compute resnc  = res0 + res00
compute ndfnc = ndf0 + ndf00

DISP '2) estimation du modèle avec contrainte, paramètres identiques sur toute la période'
LINREG lgpop
# CONSTANT ly lpg  lpnc
COMPUTE resc = %RSS
COMPUTE ndfc = %NDF

COMPUTE Fstat = (resc-resnc)/(ndfc-ndfnc)/(resnc/ndfnc)
DISPLAY 'Fstat' Fstat
CDF FTEST Fstat  ndfc-ndfnc ndfnc

DISPLAY '**Test avec une variable indicatrice** '
SET indic 1960:1 1975:1 = 0
SET indic 1976:1 1995:1 = 1
*PRINT / indic
DISP '*la variable indic prend la valeur 0 entre 1960 et 1975 et la valeur 1 sinon*'

SET Ily = indic*ly
SET Ilpg = indic*lpg
SET Ilpnc = indic*lpnc


LINREG lgpop
# CONSTANT ly lpg  lpnc indic Ily Ilpg Ilpnc
EXCLUDE
# Indic Ily Ilpg Ilpnc

DISPLAY '******************************************************************************'

DISPLAY 'test de stabilité basé sur les résidus récursifs : test du CUSUM'
LINREG(noprint) lgpop
# CONSTANT ly lpg  lpnc
*estimation avec les mco pour définir le nombre de d'observation et de variables explicatives*
COMPUTE nobs = %nobs
COMPUTE nreg = %nreg
COMPUTE  nvec  = nobs - nreg
COMPUTE tin = nreg+1
COMPUTE tfin = 1995:1


DEC VECTOR[SERIES] PER(nvec)
SET er tin tfin = 0
SET varer tin tfin = 0
SET  wr tin tfin = 0
set trend = t


DO i=1,nvec
SET per(i) = trend <nreg+I
*per(i) est une série qui permet de définir les échantillons comprenant un nombre d'observation *
*variant de K (nombre de régresseurs) à N (le nombre total d'observation)*

LINREG(smpl=per(i),noprint) lgpop
# CONSTANT ly lpg  lpnc
COMPUTE er(nreg+I)= lgpop(nreg+I)-%beta(1)-%beta(2)*ly(nreg+I)-%beta(3)*lpg(nreg+I)$
 -%beta(4)*lpnc(nreg+I)
*calcul du résidu récursif*

COMPUTE [VECTOR] xligne = || 1 , ly(nreg+I), lpg(nreg+I),lpnc(nreg+I) ||
COMPUTE  var = %QFORM(%XX,xligne)
COMPUTE  num = %scalar(var)
COMPUTE std = sqrt(1.0+num)
*calcul de l'écart-type du résidu récursif er à une constante près*

COMPUTE wr(nreg+I) = er(nreg+I) * (1.0/std)
*calcul du résidu récursif normalisé wr*

end do i

*commande RLS
*RLS(cohistory=coeff, csums=cus) lgpop
*# CONSTANT ly lpg  lpnc
*print / cus wr
*print / coeff
*estime les résidus recursif, csums donne la somme cumulée des résidus récursifs et non pas le test du cusum

STAT(NOPRINT) wr
COMPUTE %variance = %variance*(nobs-1)/(nobs-nreg-1)
*calcul de la variance des résidus récursifs normalisés*

SET wcusum = wr/sqrt(%variance)
ACC wcusum 1964:1 1995:1  cusum
*calcul de la statitique du test du CUSUM*

COMPUTE signif = 0.948*SQRT(nobs-nreg)
SET uppersignif tin tfin = signif*(1+2.0*(t-nreg)/(nobs-nreg))
SET lowersignif tin tfin = -uppersignif
*calcul de l'intervalle de confiance de la statistique*

GRAPH(header="test de stabilite du cusum") 3
# cusum 1964:1 1995:1
# uppersignif 1964:1 1995:1
# lowersignif  1964:1 1995:1

print / er wr wcusum




*****************************************************************************************************
DISPLAY 'graphique des coefficients estimés de manière récursive avec leur intervalle de confiance'
SOURCE(noecho) rlinreg.src

DISPLAY 'date initiale fixe = 1960'
@RLINREG lgpop 1960:1 1995:1 resids
# CONSTANT ly lpg  lpnc
*print / coeffs(2) coeffs(3) coeffs(4)

DISPLAY 'date initiale glissante = 1960,1961,....'
@RLINREG(WINDOW=MOVING) lgpop 1960:1 1995:1 resids
# CONSTANT ly lpg  lpnc


******************************************************************************************************
DISPLAY 'test de stabilité de Hansen'
**hypothèse nulle = paramètres constants et hypothèse alternative les paramètres suivent une martingale**

SOURCE(noecho) stabtest.src
@stabtest lgpop / stat
# CONSTANT ly lpg  lpnc