**AUTEUR : Isabelle CADORET-DAVID**

ALLOCATE 0 32
OPEN DATA probit.wks
DATA(FORMAT=wks,ORG=obs) /
print /

DISP '*********************************'
DISP '***Evaluation du modèle PROBIT***'
DISP '*********************************'

PRB grade
# CONSTANT gpa tuce psi

DISP 'calcul des effets marginaux pour psi = 1'
STATISTICS(NOPRINT) gpa
COMPUTE gpam = %mean
STATISTICS(NOPRINT) tuce
COMPUTE tucem = %mean
COMPUTE xmean1 = %beta(1)+%beta(2)*gpam+%beta(3)*tucem+%beta(4)
DISP %DENSITY(xmean1)
DISP 'effet marginal de gap' %beta(2)*%DENSITY(xmean1)
DISP 'effet marginal de tuce' %beta(3)*%DENSITY(xmean1)

DISP 'calcul des effets marginaux pour psi = 0'
COMPUTE xmean0 = %beta(1)+%beta(2)*gpam+%beta(3)*tucem
Disp 'xmean0' xmean0
DISP %DENSITY(xmean0)
DISP 'effet marginal de gap' %beta(2)*%DENSITY(xmean0)
DISP 'effet marginal de tuce' %beta(3)*%DENSITY(xmean0)

DISP 'calcul effet marginal de psi'
COMPUTE Prob1 = %CDF(xmean1)
COMPUTE Prob0 = %CDF(xmean0)
DISP 'effet marginal de psi' Prob1-Prob0

DISP 'effet marginal de psi pour les différentes valeur de gpa'
SET P1 = %CDF( %beta(1)+%beta(2)*gpa+%beta(3)*tucem+%beta(4))
SET P2 = %CDF( %beta(1)+%beta(2)*gpa+%beta(3)*tucem)
SET dP = P1-P2
Print / dp  gpa

DISP 'évaluation de la probabilté prévue par le modèle probit'
PRJ(CDF=valp)
PRINT / valp

DISP 'Test de contrainte avec test de Wald'
PRB(noprint) grade
# CONSTANT gpa tuce psi
EXCLUDE
# PSI

PRB(noprint) grade
# CONSTANT gpa tuce psi
EXCLUDE
# gpa tuce psi

DISP 'Test de contrainte avec test du ratio de vraisemblance'
PRB(noprint) grade
# CONSTANT gpa tuce psi
COMPUTE scr1 = %LOGL
PRB(noprint) grade
# CONSTANT gpa tuce
COMPUTE scr0= %LOGL
COMPUTE test1 = 2*(scr1-scr0)
DISP 'test du ratio de vraisemblance d"égalité à 0 du coeff. de PSI'
CDF  CHISQ  Test1  1

PRB(noprint) grade
# CONSTANT
COMPUTE scr00 =  %LOGL
COMPUTE test0 = 2*(scr1-scr00)
DISP 'test du ratio de vraisemblance d"égalité à 0 des tous les coeff. sauf celui de la constante'
CDF  CHISQ  Test0  3


DISP '*********************************'
DISP '***Evaluation du modèle LOGIT***'
DISP '*********************************'

LGT grade
# CONSTANT gpa tuce psi
DISP 'calcul des effets marginaux pour psi = 1'
COMPUTE xmeanl1 = %beta(1)+%beta(2)*gpam+%beta(3)*tucem+%beta(4)
COMPUTE fxmean1 = EXP(xmeanl1)/((1+EXP(xmeanl1))**2)
DISP fxmean1
DISP 'effet marginal de gap' %beta(2)*fxmean1
DISP 'effet marginal de tuce' %beta(3)*fxmean1

DISP 'calcul des effets marginaux pour psi = 0'
COMPUTE xmeanl0 = %beta(1)+%beta(2)*gpam+%beta(3)*tucem
COMPUTE fxmean0 = EXP(xmeanl0)/((1+EXP(xmeanl0))**2)
DISP fxmean0
DISP 'effet marginal de gap' %beta(2)*fxmean0
DISP 'effet marginal de tuce' %beta(3)*fxmean0

DISP 'calcul effet marginal de psi'
COMPUTE Probl1 = EXP(xmeanl1)/(1+EXP(xmeanl1))
COMPUTE Probl0 = EXP(xmeanl0)/(1+EXP(xmeanl0))
DISP 'effet marginal de psi' Probl1-Probl0

DISP 'évaluation de la probabilté prévue par le modèle logit'
PRJ vall
SET vall = EXP(vall)/(1+EXP(vall))
PRINT / vall