**AUTEUR : Isabelle CADORET-DAVID**

ALLOCATE 72
OPEN DATA cartecreditrats.xls
DATA(FORMAT=xls,ORG=obs) /
PRINT /


DISPLAY '***estimation avec la méthode des MCO***'
LINREG Depenses / resids
# CONSTANT age prop revenu revenu2
*estimation MCO*

SET resid2 = resids**2   ;*autre commande rats possible SET resids2 = %resids**2*
COMPUTE scr = %RSS
DISPLAY scr
*calcul du carré des résidus et la somme des carrés des résidus*


SCAT(STYLE=SYMBOL,HMAX=6000) 1
# resid2 revenu
*graphique du carré des résidus en fonction du revenu*

DISPLAY '***Test de White***'
SET age2 = age**2
SET revenu4 = revenu2**2
SET ageprop = age*prop
SET agerev = age*revenu
SET agerev2 = age*revenu2
SET proprev = prop*revenu
SET proprev2 = prop*revenu2
SET revrev2 = revenu * revenu2

LINREG resid2
# CONSTANT age prop revenu revenu2 age2 revenu4 ageprop agerev agerev2 $
proprev proprev2 revrev2

compute TW = %nobs*%rsquared   ;*commande rats plus rapide %trsquared*
DISPLAY 'statistique de White' TW

CDF  CHISQ  TW (%NREG-1)
*niveau de significativité du test*

DISPLAY '***Test de White modifié***'
LINREG resid2 / resids
# CONSTANT revenu revenu2
COMPUTE lm =  %nobs*%rsquared
DISPLAY 'statistique du multiplicatuer de lagrange' lm
CDF  CHISQ  lm (%NREG-1)


DISPLAY '***Test de Goldfeld - Quandt***'
ORDER revenu / depenses age prop revenu2
print / revenu depenses
*range par ordre de croissant du revenu les séries*

LINREG Depenses 1 32
# CONSTANT age prop revenu revenu2
COMPUTE res1 = %RSS
COMPUTE ndf1 = %NDF
*estime le modèle sur les 32 premières observations classées*

LINREG Depenses 41 72
# CONSTANT age prop revenu revenu2
COMPUTE res2 = %RSS
COMPUTE ndf2 = %NDF
*estime le modèle sur les 32 dernières observations classées*

COMPUTE Fstat = (res2/ndf2)/(res1/ndf1)
DISPLAY 'Fstat' Fstat
CDF FTEST Fstat  ndf1 ndf2

DISPLAY '***estimation avec la méthode des MCG****'
DISPLAY '**premier cas : la variance des aléas est fonction de la variable revenu***'
LINREG(SPREAD=revenu) Depenses
# CONSTANT age prop revenu revenu2

DISPLAY '**second cas : la variance des aléas est fonction de la variable revenu2***'
LINREG(SPREAD=revenu2) Depenses
# CONSTANT age prop revenu revenu2


DISPLAY '**estimation avec la méthode des mco, mais avec calcul de la matrice de variance covariance***'
LINREG(ROBUSTERRORS) Depenses
# CONSTANT age prop revenu revenu2