OPEN DATA modmacro.wks
CAL 1947 1 4
ALL 1988:1
DATA(FORMAT=wks,ORG=obs)


***définition des équations***
EQUATION MO M
# CONSTANT taux
EQUATION MD M
# CONSTANT taux{1} GNP
DISP '*****************************************************************************'
DISP '***Estimation du modele macro avec la méthode des MCO***'
DISP '*****************************************************************************'
LINREG(EQUATION=MO)
LINREG(EQUATION=MD)

DISP '*****************************************************************************'
DISP '***Estimation du modele macro avec la méthode des TMC***'
DISP '*****************************************************************************'

INSTRUMENT CONSTANT taux{1} GNP
SUR(INST) 2
# MO
# MD

DISP '*****************************************************************************'
DISP '***Calcul des multiplicateurs ***'
DISP '*****************************************************************************'
DEC RECTANGULAR[real] MATA(2,2)
DEC RECTANGULAR[real] MATB(2,2)
DEC RECTANGULAR[real] MATC(2,2)
DEC RECTANGULAR[real] MATD(2,2)
DEC RECTANGULAR[real] MATE(2,2)
DEC RECTANGULAR[real] MATF(2,2)


COMPUTE MATA(1,1) = 1.0
COMPUTE MATA(1,2) = -%beta(2)
COMPUTE MATA(2,1) = 1.0
COMPUTE MATA(2,2) = 0.0

COMPUTE MATB(1,1) = 0.0
COMPUTE MATB(1,2) = 0.0
COMPUTE MATB(2,1) = 0.0
COMPUTE MATB(2,2) = %beta(4)

COMPUTE MATC(1,1) = %beta(1)
COMPUTE MATC(1,2) = 0
COMPUTE MATC(2,1) = %beta(3)
COMPUTE MATC(2,2) = %beta(5)


COMPUTE MATD = INV(MATA)*MATB
COMPUTE MATE = INV(MATA)*MATC
COMPUTE MATF = INV(%IDENTITY(2)-MATD)*MATE


DISP 'effet d"une variation du PNB sur M à court terme' MATE(1,2)
DISP 'effet d"une variation du PNB sur TAUX à court terme' MATE(2,2)
DISP 'effet d"une variation du PNB sur M à long terme' MATF(1,2)
DISP 'effet d"une variation du PNB sur TAUX à long terme' MATF(2,2)

COMPUTE MEQUI   = MATF(1,1)+MATF(1,2)*GNP(1988:1)
COMPUTE TAUXEQUI = MATF(2,1)+MATF(2,2)*GNP(1988:1)
DISP 'valeurs d"équilibre' MEQUI TAUXEQUI



DISP '*****************************************************************************'
DISP '***Analyse de la stabilité du modèle***'
DISP '*****************************************************************************'
EIGEN(cvalues=CEIGVAL,cvector=CEIGVEC) MATD EIGVAL EIGVEC
DISP 'VALEURS PROPRES REELLES ET COMPLEXES'
WRITE EIGVAL
WRITE CEIGVAL