**AUTEUR : Isabelle CADORET-DAVID**

CALENDAR 1922 1 1
ALLOCATE 1941:1
OPEN DATA marchekmenta.wks
DATA(FORMAT=wks,ORG=obs) /
PRINT /


DISP '****définition des équations*****'

EQUATION demande q
# CONSTANT p dd
EQUATION offre q
# CONSTANT p f a

DISP '****estimation avec la méthode des MCO*****'

*LINREG(EQUATION=demande) q
*LINREG(EQUATION=offre) q

DISP '****estimation avec la méthode des DMC*****'

INST CONSTANT dd f a
LINREG(EQUATION=demande, INST) q
LINREG(EQUATION=offre, INST) q


DISP '****estimation avec la méthode des TMC*****'

SUR(INST,iters=100) 2
# demande
# offre

DISP '****redéfinition du système d"équations en mun modèle dynamique*****'

EQUATION demande q
# CONSTANT p p{1}  dd
EQUATION offre q
# CONSTANT p q{1} f a
INST CONSTANT dd f a p{1}  q{1}
LINREG(EQUATION=demande, INST) q
COM betad =%beta
LINREG(EQUATION=offre, INST) q
COM betao = %beta

DEC RECTANGULAR[real] MATY(2,2)
DEC RECTANGULAR[real] MATX(2,4)
DEC RECTANGULAR[real] MATY1(2,2)
DEC RECTANGULAR[real] MATP(2,4)
DEC RECTANGULAR[real] MATD(2,2)
DEC RECTANGULAR[real] IMATD(2,2)
DEC RECTANGULAR[real] MATL(2,4)

COMPUTE MATY = ||1,-betad(2)| $
                 1,-betao(2)||

COMPUTE MATX = ||betad(1), betad(4), 0, 0 | $
                 betao(1), 0, betao(4), betao(5)||

COMPUTE MATY1 = ||0,betad(3)| $
                 betao(3),0||

DISP 'analyse de la stabilité'
COMPUTE MATD = INV(MATY)*MATY1
EIGEN(cvalues=CEIGVAL) MATD EIGVAL EIGVEC
DISP 'VALEURS PROPRES REELLES ET COMPLEXES'
WRITE EIGVAL
WRITE CEIGVAL

DISP 'multiplicateur de court terme'
COMPUTE MATP = INV(MATY)*MATX
DISP MATP

DISP 'multiplicateur de long terme'
COMPUTE  IMATD = %identity(2) - MATD
COMPUTE  MATL = INV(IMATD)*MATP
DISP MATL