/* **************************************************************************** */
/* CHAPITRE 10 - MODELISATION D'UN SYSTEME DE DEMANDE DE FACTEURS DE PRODUCTION */
/* **************************************************************************** */

* ----------------------------------------------------------------------------- ;
* xL	: quantité de travail                                                   ;
* xK	: quantité de capital                                                   ;
* xCI	: quantité de consommations intermédiaires                              ;
* wL	: coût du travail                                                       ;
* wK	: coût du capital                                                       ;
* wCI	: prix des consommations intermédiaires                                 ;
* pv	: prix de l'output                                                      ;
* vent	: niveau des ventes de l'output                                         ;
* ----------------------------------------------------------------------------- ;

libname exo 'Z:\Econometrie appliquee\donnees';

ods pdf file="Z:\Econometrie appliquee\Resultats\chapitre10.pdf";
title;
* ------------------------------------------------------------------- ;
* Probleme n°10.1 : construction des variables et analyse descriptive ;  
* ------------------------------------------------------------------- ;

* Point 1 :transformation des variables ;
* ------------------------------------- ;
data chapit10;
  set exo.chapit10;
  date = intnx( 'year', '01jan1978'd, _n_-1 );	* Création de la var DATE ;
  format date year4.;
  qy = vent / pv;								* Niveau de production ;
  wk80 = (wk / 11.85)*100;						* Année de référence : 1980 ;
  wl80 = (wl / 98.5633)*100;					* Année de référence : 1980 ;
run;


* Point 2 : calcul des parts de dépenses par rapport au cout total ;
* ---------------------------------------------------------------- ;
data chapit10;
  set chapit10;
  ct = wk80*xk + wl80*xl + wci*xci;
  sk = (wk80*xk) / ct; 							* Part du facteur K ;
  sl = (wl80*xl) / ct; 							* Part du facteur L ;
  sci = (wci*xci) / ct; 						* Part du facteur CI ;
  soms = sk + sl + sci;							* Validation => somme = 1 ;
run;


* Point 3 : analyse graphique des variables ;
* ----------------------------------------- ;
* a. Evolution des prix ;
* --------------------- ;
goption reset=all;
		legend1
		frame
		across=1
		mode=share
		position= (top left)
		offset=(17 pct, -6 pct)
		cshadow=grey;
axis1 label=none order=(0 to 250 by 50) width=1 value=(h=1); 
axis2  width=1 value=(h=1); 

proc gplot data=chapit10;
  symbol1 value=none i=join color=blue line=1;
  symbol2 value=none i=join color=red line=1;
  symbol3 value=none i=join color=green line=1;
  symbol4 value=none i=join color=magenta line=1;
  plot (pv wci wl80 wk80)*date / overlay legend=legend1 haxis=axis2 vaxis=axis1;
  format date year4.;
  title "Evolution des prix";
run;
title ' ';
quit;

* b. Intensité de chaque facteur ;
* ------------------------------ ;
data chapit10;
  set chapit10;
  ik = xk / qy;
  il = xl / qy;
  ici = xci / qy;
run;

axis1 label=none order=(0 to 1.4 by 0.2) width=1 value=(h=1); 
axis2  width=1 value=(h=1); 
axis3 label=none order=(0 to 70 by 10) width=1 value=(h=1); 

proc gplot data=chapit10;
  symbol i=join;
  plot (il ici)*date / overlay legend haxis=axis2 vaxis=axis1;
  plot2 ik*date / overlay legend haxis=axis2 vaxis=axis3;
  format date year4.;
  title "Intensite de chaque facteur";
run;
title ' ';
quit;

* ----------------------------------------------------------- ;
* Probleme n°10.2 : estimation du systeme de parts de dépense ;  
* ----------------------------------------------------------- ;

* Point 1 : transformation des variables en log ;
* --------------------------------------------- ;
data chapit10;
  set chapit10;
  lwk80 = log(wk80);
  lwl80 = log(wl80);
  lwci = log(wci);
  lwkci = log(wk80/wci);
  lwlci = log(wl80/wci);
  lwlk = log(wl80/wk80);
  lwcik = log(wci/wk80);
run;

* Point 2 : estimation par les MCO ;
* -------------------------------- ;
proc reg data=chapit10;
  model sk = lwlci lwkci;
  model sl = lwlci lwkci;
  model sci = lwlci lwkci;
  title "Estimation par les MCO";
run;
title " ";
quit;

* Point 3 : methode de Zellner ;
* ---------------------------- ;

* systeme 1 ;
* --------- ;
proc syslin data=chapit10 SUR outest=coeff1 covout ;
  sk : model sk = lwlci lwkci / dw;
  sl : model sl = lwlci lwkci / dw;
  srestrict sk.lwlci = sl.lwkci ;
  title "Estimation du système 1 par la méthode de Zellner";
run;

* systeme 2 ;
* --------- ;
data chapit10;
  set chapit10;
  lwlk = log(wl80/wk80);
  lwcik = log(wci/wk80);
run;

proc syslin data=chapit10 SUR outest=coeff2 covout ;
  sl  : model sl  = lwcik lwlk / dw;
  sci : model sci = lwlk lwcik / dw;
  srestrict sl.lwcik = sci.lwlk ;
  title "Estimation du système 2 par la méthode de Zellner";
run;


* Point 4 : methode de Zellner itérative ;
* -------------------------------------- ;

* Systeme 1 ;
* --------- ;
proc syslin data=chapit10 ITSUR outest=coeff3 covout ;
  sk : model sk = lwlci lwkci / dw ;
  sl : model sl = lwlci lwkci / dw ;
  srestrict sk.lwlci = sl.lwkci ;
  title "Estimation du système 1 par la méthode de Zellner itérative";
run;

* Systeme 2 ;
* --------- ;
proc syslin data=chapit10 ITSUR outest=coeff4 covout ;
  sl  : model sl  = lwcik lwlk ;
  sci : model sci = lwlk lwcik ;
  srestrict sl.lwcik = sci.lwlk ;
  title "Estimation du système 2 par la méthode de Zellner itérative";
run;

* Calcul des coefficients de l'équation omise ;
* ------------------------------------------- ;
data elastic;
  set coeff3 (firstobs=1 obs=1);
  drop _TYPE_ _STATUS_ _MODEL_ _DEPVAR_ _NAME_ _SIGMA_ sk sl;
run;

data elastic2;
  set coeff3 (firstobs=5 obs=5);
  drop _TYPE_ _STATUS_ _MODEL_ _DEPVAR_ _NAME_ _SIGMA_ sk sl;
  rename intercept=int2 lwlci=lwlci2 lwkci=lwkci2;
run;

data elastic3;
  set coeff4 (firstobs=1 obs=1);
  drop _TYPE_ _STATUS_ _MODEL_ _DEPVAR_ _NAME_ _SIGMA_ sci sl;
run;

data elastic4;
  set coeff4 (firstobs=5 obs=5);
  drop _TYPE_ _STATUS_ _MODEL_ _DEPVAR_ _NAME_ _SIGMA_ sci sl;
  rename intercept=int2 lwlk=lwlk2 lwcik=lwcik2;
run;

data elastic5;
  set elastic;
  set elastic2;
  intc=1-intercept-int2;
  ccik=-lwlci-lwkci;
  ccil=-lwlci2-lwkci2;
  ccici=-ccik-ccil;
run;

data elastic6;
  set elastic3;
  set elastic4;
  intd=1-intercept-int2;
  dkl=-lwlk-lwcik;
  dkci=-lwcik2-lwlk2;
  dkk=-dkl-dkci;
run;

proc print data=elastic5 noobs;
  var intc ccik ccil ccici;
  title "Déduction des coefficients de l'équation omise SCI";
run;

proc print data=elastic6 noobs;
  var intd dkl dkci dkk;
  title "Déduction des coefficients de l'équation omise SK";
run;

ods pdf close;