/* ******************************************************************** */
/*   chapit 02 - EVALUATION DE LA RELATION EPARGNE-INVESTISSEMENT       */ 
/* ******************************************************************** */

libname exo 'Z:\Econometrie appliquee\donnees';

ods pdf file="Z:\Econometrie appliquee\Resultats\chapitre02.pdf";
title;

/* -------------------------------------------------------------------- */
/*   1 - EVALUATION DU DEGRE DE MOBILITE DU CAPITAL A LONG TERME        */ 
/* -------------------------------------------------------------------- */

* ---------------------------------------------------------------------- ;
* pays			: 19 pays de l'OCDE                                      ;
* txi7098		: Taux d'investissement moyen sur la période 1970-1998   ;
* txi9098		: Taux d'investissement moyen sur la période 1990-1998   ;
* txs7098		: Taux d'épargne nationale moyen sur la période 1970-1998;
* txs9098		: Taux d'épargne nationale moyen sur la période 1990-1998;
* txsprive7098	: Taux d'épargne privée moyen sur la période 1970-1998   ;
* txsprive9098	: Taux d'épargne privée moyen sur la période 1990-1998   ;
* txspub7098	: Taux d'épargne publique moyen sur la période 1970-1998 ;
* txspub9098	: Taux d'épargne publique moyen sur la période 1990-1998 ;
* dc7098		: Déficit commercial /PIB moyen sur la période 1970-1998 ;
* txi7074		: Taux d'investissement moyen sur la période 19970-1974  ;
* txs7074		: Taux d'épargne nationale moyen sur la période 1970-1974;
* txsprive7074	: Taux d'épargne privée moyen sur la période 1970-1974   ;
* txspub7074	: Taux d'épargne publique moyen sur la période 1970-1974 ;
* txi7079		: Taux d'investissement moyen sur la période 1970-1979   ;
* txs7079		: Taux d'épargne nationale moyen sur la période 1970-1979;
* txsprive7079	: Taux d'épargne privée moyen sur la période 1970-1979   ;
* txspub7079	: Taux d'épargne publique moyen sur la période 1970-1979 ;
* txi8089		: Taux d'investissement moyen sur la période 1980-1989   ;
* txs8089		: Taux d'épargne nationale moyen sur la période 1980-1989;
* txsprive8089	: Taux d'épargne privée moyen sur la période 1980-1989   ;
* txspub8089	: Taux d'épargne publique moyen sur la période 1970-1998 ;
* ---------------------------------------------------------------------- ;

* 1.1 - Estimation du modèle de Feldstein et Horioka ;
* -------------------------------------------------- ;

* a) Estimation par la méthode des MCO de l'équation txi7098 = f(txs7098) ;
*    pour les 19 pays de l'échantillon                                    ;

proc reg data=exo.chapit02 simple outest=res_19;
  model txi7098 = txs7098 / dw sse mse r p ;
  plot txi7098*txs7098 / cframe=ligr ;
  output out=reglin18 p=phat18;
run;
quit;

data exo.chapit02;
  set exo.chapit02;
  len=LENGTH(pays);
run;
proc sort data=exo.chapit02;
  by len;
run;

goption reset=global;
proc gplot data=reglin18 ;
  symbol1 color=blue i=none value=dot h=0.5 pointlabel=("#pays");
  symbol2 color=red i=join value=none;
  format pays $11.;
  plot (txi7098 phat18)*txs7098 / overlay; 					
run;
quit;

data exo.chapit02;
  set exo.chapit02;
  drop len;
run;

* b1) Estimation par la méthode des MCO de l'équation txi7098 = f(txs7098) ;
*    pour les 15 premiers pays de l'échantillon                           ;

data exo.chapit02_15;
  set exo.chapit02;
  if pays in('Suede','Suisse','Australie','Royaume-Uni') then delete;
run;

proc reg data=exo.chapit02_15 simple outest=res_15;
  model txi7098 = txs7098 / dw sse mse r p ;
  plot txi7098*txs7098=pays /cframe=ligr ;
  output out=reglin15 p=phat15;
run;
quit;

* b2) Comparaison des estimations issues d'échantillons de taille différente ;
proc sort data=reglin18; by pays; run;
proc sort data=reglin15; by pays; run;

data reglin_fus;
  merge reglin18(keep=pays phat18 txs7098) reglin15(keep=pays phat15 txs7098);
  by pays;
run;

data reglin_fus;
  set reglin_fus;
  label phat18="18 pays" 
        phat15="15pays";
run;

goption reset=global;
symbol1 i=j c=blue v=none;
symbol2 i=j c=red v=none;
axis1 label=("Taux d'épargne") 
      order=(0.16 to 0.34 by 0.02)
      ;
axis2 label=(angle=90 "Taux d'investissement") 
      order=(0.18 to 0.30 by 0.02)
	   ;

legend1 label=none
        shape=symbol(4,2)
        position=(top center inside)
        mode=share;

proc gplot data=reglin_fus;
  plot (phat18 phat15)* txs7098 / overlay legend=legend1 hminor=0 vminor=0
                                  cframe=ligr haxis=axis1 vaxis=axis2;
run;
quit;


* c) Calcul de l'intervalle de confiance du paramètre spécifique à la var.  ;
*    txs7098                                                                ; 

proc reg data=exo.chapit02;
  model txi7098 = txs7098 / clb;
run;
quit;

* d) Estimation par la méthode des MCO de l'équation txi = f(txs) sur les     ;
*    sous-périodes 1970-1979, 1980-1989 et 1990-1998                          ; 

proc reg data=exo.chapit02; 
  model txi7079 = txs7079 / clb;
  model txi8089 = txs8089 / clb;
  model txi9098 = txs9098 / clb;
run;
quit;

* e) Estimation par la méthode des MCO de l'équation txi7074 = f(txs7074) et  ;
*    comparaison des résultats à ceux de Feldstein et Horioka                 ; 

proc reg data=exo.chapit02 ; 
  model txi7074 = txs7074 / clb;
run;
quit;


* 1.2 - Extension du modèle initial : vers un modèle de régression multiple...;
* --------------------------------------------------------------------------- ;

* a) Estimation par la méthode des MCO de l'équation txi = f(txsprive,txspub) ;
*    sur les périodes 1970-1998, 1970-1979, 1980-1989 et 1990-1998            ; 

proc reg data=exo.chapit02 ; 
  model txi7098 = txsprive7098 txspub7098 / clb;
  test1_7098: test txsprive7098=txspub7098=0; 
  test2_7098: test txsprive7098=txspub7098; 

  model txi7079 = txsprive7079 txspub7079 / clb;
  test1_7079: test txsprive7079=txspub7079=0; 
  test2_7079: test txsprive7079=txspub7079; 

  model txi8089 = txsprive8089 txspub8089 / clb;
  test1_8089: test txsprive8089=txspub8089=0; 
  test2_8089: test txsprive8089=txspub8089; 

  model txi9098 = txsprive9098 txspub9098 / clb;
  test1_9098: test txsprive9098=txspub9098=0; 
  test2_9098: test txsprive9098=txspub9098; 
run;
quit;

* b) Procéde aux étapes suivantes sur les données calculées en moyenne sur la  ;
*    période 1990-1998 :                                                       ;
*     - estimer par la méthode des MCO l'équation txi9098 = f(txsprive9098)    ;
*          --> on note RES1 les résidus MCO de cette équation                  ;
*     - estimer par la méthode des MCO l'équation txspub9098 = f(txsprive9098) ;      
*          --> on note RES2 les résidus MCO de cette équation                  ;
*     - estimer par la méthode des MCO l'équation res1 = f(res2)               ;      

proc reg data=exo.chapit02 ; 
  model txi9098 = txsprive9098 ;
  output out=result1 r=res1;
run;
quit;

proc reg data=exo.chapit02 ; 
  model txspub9098 = txsprive9098 ;
  output out=result2 r=res2;
run;
quit;

proc sort data=result1; by pays; run; 
proc sort data=result2; by pays; run; 

data result;
  merge result1 result2;
  by pays;
run;

proc reg data=result; 
  model res1 = res2 ;
run;
quit;

proc reg data=exo.chapit02 ; 
  model txi9098 = txsprive9098 txspub9098 ;
run;
quit;


* 1.3 - Test du degré de mobilité des capitaux et déficit commercial ;
* ------------------------------------------------------------------ ;

* a) Estimation par MCO de l'équation dc7098 = f(pimm,pexm) = f(txs7098) ;
*    où PIMM = part des importations et PEXM = part des exportations     ; 

proc reg data=exo.chapit02 ; 
  model dc7098 = txs7098 / clb;
run;
quit;

* b) Décomposition du taux d'épargne nationale en taux d'épargne privée        ;
*    et taux d'épargne publique                                                ; 

* Décomposition de l'épargne nationale : DC =F(TXSPRIVE , TXSPUB)              ;
proc reg data=exo.chapit02 ; 
  model dc7098 = txsprive7098 txspub7098;
  test: test txsprive7098=txspub7098; 
run;
quit;

ods pdf close;