DISPLAY '*******************************************************'
DISPLAY "LA FONCTION D'OFFRE DE VIANDE BOVINE"
DISPLAY '*******************************************************'

CALENDAR 1953
*précise l'année de départ

ALLOCATE 1998:1
*Spécifie la date de la dernière entrée

OPEN DATA chapitre8.xls
*ouverture du fichier de données

DATA(FORMAT=XLS,ORG=COLS)
*description du fichier de données

PRINT /
*imprime toutes les séries du fichier

*******************************************************
*            Intitulé des différentes séries          *
*******************************************************

/*
q = production bovine française
p = prix du boeuf à la consommation (francs constants 1970)
w = prix des aliments du bétail (francs constants 1980)
*/

DISPLAY '*******************************************************'
DISPLAY 'Problème n°1 : Construction des variables'
DISPLAY 'et analyse descriptive'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

COMPUTE p90 = p(1990:1)
SET p = p/p90*100
COMPUTE w90 = w(1990:1)
SET w = w/w90*100
*transformation des variables de prix en base 1990*

DISPLAY 'QUESTION 2'

GRAPH(KEY=UPLEFT,OVERLAY=LINE,OVCOUNT=1) 2
# q
# p
*création d'un graphe représentant l'indice de prix du boeuf à*
*la production et la production de viande bovine*

GRAPH(KEY=UPLEFT) 2
# p
# w

DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : Estimation de l"équation d"offre'
DISPLAY 'dans le cadre d"un modèle à la Nerlove'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 2'

LINREG q
# CONSTANT p{1} q{1} w{1}
*estimation de la fonction d'offre par les mco*

COMPUTE denom=1-%NOBS*%SEESQ*%XX(3,3)
IF denom>0
   COMPUTE h=%rho*SQRT(%NOBS/denom)
ELSE
   COMPUTE h=0.0
END IF
DISP 'statistique h de durbin' h
*test de l'hypothèse d'autocorrélation d'ordre 1 des résidus*
*calcul de la statistique h de durbin*

DISPLAY 'QUESTION 3'

*test d'Hausman - test d'exogeneite de la quantitée décalée sur l'équation d'offre en utilisant la régression augmentée*
SET q1 = q{1}
LINREG q1 / resids
# CONSTANT p{1} w{1} w{2}
*test d'Hausman - étape 1*
LINREG q
# CONSTANT p{1} q{1} w{1} resids
*test d'Hausman - étape 2, estimation de la régression augmentée*

*test d'Hausman - test d'exogeneite de la quantitée décalée dans l'équation d'offre en utilisant la statistique de wald*
*solution alternative à la précédente*
INSTRUMENT CONSTANT p{1} w{1} w{2}
LINREG(INST) q
# CONSTANT p{1} q{1} w{1}
*estimation du modèle avec la méthode des Variables Instrumentales, on remarque que les paramètres estimés ont la même valeur*
*que ceux obtenus dans la régression augmentée (étape 2 précédente)*

COMPUTE [symmetric] covvi=%seesq*%xx
COMPUTE [vector] betavi=%beta
*sauvegarde de la matrice de variance-covariance et du vecteur des paramètres*

LINREG q
# CONSTANT p{1} q{1} w{1}
*estimation du modèle avec la méthode des MCO*

COMPUTE [symmetric] covmco=%seesq*%xx
COMPUTE [vector] betamco=%beta
COMPUTE vbeta =betavi-betamco
*sauvegarde de la matrice de variance-covariance et du vecteur des paramètres*

COMPUTE vvar = covvi-covmco
COMPUTE ivvar = inv(vvar)
COMPUTE wald = %qform(ivvar,vbeta)
CDF CHISQ wald 1
*calcul de la statistique de wald*


DISPLAY '*******************************************************'
DISPLAY 'Problème n°3 : Calcul des élasticités de court terme'
DISPLAY 'et de long terme. Utilisation des variables muettes'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

LINREG q
# CONSTANT p{1} q{1} w{1}

*Calcul des élasticites avec comme année de référence 1990 :

COMPUTE ectb = %BETA(2)*(p(1990:1)/q(1990:1))
DISPLAY 'élasticité court terme par rapport au prix du boeuf =' ectb

COMPUTE eltb = (%BETA(2)/(1-%BETA(3)))*(p(1990:1)/q(1990:1))
DISPLAY 'élasticité long terme par rapport au prix du boeuf =' eltb

COMPUTE ecta = %BETA(4)*(w(1990:1)/q(1990:1))
DISPLAY 'élasticité court terme par rapport au prix des aliments du betail =' ecta

COMPUTE elta = (%BETA(4)/(1-%BETA(3)))*(p(1990:1)/q(1990:1))
DISPLAY 'élasticité long terme par rapport au prix des aliments du betail =' elta

DISPLAY 'QUESTION 2'

COMPUTE ca = 1-%BETA(3)
DISPLAY 'coefficient d ajustement partiel =' ca

DISPLAY 'QUESTION 3'

SET d74 = an==1974
*création d'une dummy pour l'année 1974*
LINREG q
# CONSTANT p{1} q{1} w{1} d74

SET d96 = an==1996
LINREG q
# CONSTANT p{1} q{1} w{1} d96

DISPLAY 'QUESTION 4'

SET d93 = an>1992
LINREG q
# CONSTANT p{1} q{1} w{1} d93

SET d93p = d93*p{1}
LINREG q
# CONSTANT p{1} q{1} w{1} d93p

DISPLAY '*******************************************************'
DISPLAY 'Problème n°4 : Extension'
DISPLAY '*******************************************************'

LINREG q
# CONSTANT p{1 to 3} q{1} w{1} d74

OPEN COPY donnees_chap8.xls
COPY(FORMAT=XLS,ORG=COLS) / q p w
*sauvegarde les données sous le format xls
*afin de réaliser les graphiques sous Excel