DISPLAY '*******************************************************'
DISPLAY "LE MODELE D'EVALUATION DES ACTIFS FINANCIERS"
DISPLAY '*******************************************************'
CALENDAR(WEEKLY) 1989 12 29
*CALENDAR(WEEKLY) 1990 1 1

*CALENDAR 90 1 52
*précise la fréquence des données et l'année de départ
*données hebdomadaires, départ 1990 première semaine

*ALLOCATE 99:52
*spécifie la longueur des séries

OPEN DATA chapitre7.wks
*ouverture du fichier de données

DATA(FORMAT=wks,ORG=obs)
*description du fichier de données

PRINT /
*impression de toutes les séries du fichier

*******************************************************
*                 Intitulé des séries                 *
*******************************************************

/*
cac  =	valeur de l'indice CAC40 en points
cacpi =	série de price index de la série de CAC40
cacri =	série de return index de la série de CAC40
pib1m =	taux de placement sans risque (taux PIBOR à un mois)
bnp =	valeur du titre en euro de la BNP
bnppi =	série de price index de la série de la BNP
bnpri =	série de return index de la série de la BNP
peu =	valeur du titre en euro de Peugeot
peupi =	série de price index de la série de Peugeot
peuri =	série de return index de la série de Peugeot
car =	valeur du titre en euro de Carrefour
carpi =	série de price index de la série de Carrefour
carri =	série de return index de la série de Carrefour
fra =	valeur du titre en euro de France Telecom
frapi =	série de price index de la série de France Telecom
frari =	série de return index de la série de France Telecom
cap =	valeur du titre en euro de Cap Gemini
cappi =	série de price index de la série de Cap Gemini
capri =	série de return index de la série de Cap Gemini
elf = valeur du titre en euro de ELF
elfpi =	série de price index de la série de ELF
elfri =	série de return index de la série de ELF
can =	valeur du titre en euro de Canal+
canpi =	série de price index de la série de Canal+
canri =	série de return index de la série de Canal+
*/

DISPLAY '*******************************************************'
DISPLAY 'Problème n°1 : estimation par les mco '
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

SET r =pib1m/52
*r = taux sans risque hebdomadaire

SET rcac = 100*(cacri-cacri{1})/cacri{1}
*création de la variable de taux de rendement qui correspond au taux de croissance du return index
*rcac = taux de croissance du Return Index du CAC40 en %

SET  rbnp = 100*(bnpri-bnpri{1})/bnpri{1}
SET  rcan = 100*(canri-canri{1})/canri{1}
SET  rcap = 100*(capri-capri{1})/capri{1}
SET  rcar = 100*(carri-carri{1})/carri{1}
SET  relf = 100*(elfri-elfri{1})/elfri{1}
SET  rfra = 100*(frari-frari{1})/frari{1}
SET  rpeu = 100*(peuri-peuri{1})/peuri{1}

SET ecac = rcac-r
*ecac = primes de risque ou excès de rendement pour le CAC40

SET ebnp = rbnp-r
SET ecan = rcan-r
SET ecap = rcap-r
SET ecar = rcar-r
SET eelf = relf -r
SET efra = rfra-r
SET epeu = rpeu-r

SPGRAPH(HEADER="Profils des séries",SUBHEADER="medaf",HFIELDS=1,VFIELDS=2)
*indique a RATS de réaliser les graphiques suivants sur une même page qui
*aura pour titre "Profils des séries" et pour sous-titre "medaf", les 4
*graphiques seront disposés verticalement

GRAPH(KEY=upl,HEADER="Figure 1a : indice cac 40") 1
# cac
*réalisation du graphique représentant l'évolution de la variable cac, ce
*graphique aura pour titre "indice cac 40", la légende se situera en haut
*à gauche

GRAPH(KEY=upl,HEADER='Figure 1b : taux sans risque') 1
# r
SPGRAPH(DONE)
*fin de l'instruction SPGRAPH

SPGRAPH(HEADER="Séries de Price Index",SUBHEADER="medaf",HFIELDS=2,VFIELDS=1)

GRAPH(KEY=upl,HEADER="Figure 2a : Séries de Price Index") 7
# bnppi
# peupi
# carpi
# frapi
# cappi
# elfpi
# canpi

GRAPH(KEY=upl,HEADER="Figure 2b : Séries de Return Index") 7
# bnpri
# peuri
# carri
# frari
# capri
# elfri
# canri

SPGRAPH(DONE)

SPGRAPH(HEADER="Séries d'excès de rendement",SUBHEADER="medaf",HFIELDS=1,VFIELDS=2)
GRAPH(KEY=upl,HEADER="Figure 3a : ELF - CAC40") 2
# eelf
# ecac

GRAPH(KEY=upl,HEADER="Figure 3b : Canal+ - CAC40") 2
# ecan
# ecac
SPGRAPH(DONE)

DISPLAY 'QUESTION 2'

LINREG ebnp / resbnp
# ecac constant
LINREG ecan / rescan
# ecac constant
LINREG ecap / rescap
# ecac constant
LINREG ecar / rescar
# ecac constant
LINREG eelf / reself
# ecac constant
LINREG efra / resfra
# ecac constant
LINREG epeu / respeu
# ecac constant


SPGRAPH(HEADER="Séries des résidus mco",HFIELDS=2,VFIELDS=4)
GRAPH(KEY=upl,HEADER='Figure 4a : BNP ') 1
# resbnp
GRAPH(KEY=upl,HEADER='Figure 4b : Canal +') 1
# rescan
GRAPH(KEY=upl,HEADER='Figure 4c : Cap gémini') 1
# rescap
GRAPH(KEY=upl,HEADER='Figure 4d : Carrefour') 1
# rescar
GRAPH(KEY=upl,HEADER='Figure 4e : Elf') 1
# reself
GRAPH(KEY=upl,HEADER='Figure 4f : France Telecom') 1
# resfra
GRAPH(KEY=upl,HEADER='Figure 4g : Peugeot') 1
# respeu
SPGRAPH(done)





DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : Test et correction de l"autocorrélation'
DISPLAY '*******************************************************'


DISPLAY 'QUESTION 2'

AR1(METHOD=CORC) ebnp
# ecac constant
*estimation avec correction de l'autocorrélation d'ordre 1 des résidus
*avec la méthode de Cochrane Orcutt
AR1(METHOD=CORC) ecap
# ecac constant
AR1(METHOD=HILU) ebnp
# ecac constant
AR1(METHOD=HILU) ecap
# ecac constant



*estimation avec correction de l'autocorrélation d'ordre 1 des résidus
*avec la méthode de Hildreth-Lu

DISPLAY '*******************************************************'
DISPLAY 'Problème n°3 : tests sur les coefficients alpha et beta'
DISPLAY '*******************************************************'

DISPLAY "'QUESTION 2'"
DISP 'Cap Gémini - Statistique Tstatb'
AR1(METHOD=CORC,NOPRINT) ecap
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'Canal+ - Statistique Tstatb'
LINREG(NOPRINT) ecan
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'BNP - Statistique Tstatb'
AR1(METHOD=CORC,NOPRINT) ebnp
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'Carrefour - Statistique Tstatb'
LINREG(NOPRINT) ecar
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'ELF - Statistique Tstatb'
LINREG(NOPRINT) eelf
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'France Telecom - Statistique Tstatb'
LINREG(NOPRINT) efra
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf

DISP 'Peugeot - Statistique Tstatb'
LINREG(NOPRINT) epeu
# ecac constant
COMPUTE tstatb = (%BETA(1) - 1) / (sqrt(%SEESQ*%XX(1,1)))
CDF TTEST tstatb %ndf