DISPLAY '*******************************************************'
DISPLAY 'ANALYSE DE LA CONVERGENCE'
DISPLAY '*******************************************************'

ALLOCATE 28
*alloue un espace de 28 observations en mémoire

OPEN DATA  chapitre4.xls
*ouverture du fichier de données

DATA(FORMAT=XLS,ORG=COLS) /
*description du fichier de données

PRINT /
*imprime toutes les séries du fichier

*******************************************************
*           Intitulé des différentes séries           *
*******************************************************

/*
logy2000 = logarithme du PIB par tête en 2000
logy70 = logarithme du PIB par tête en 1970
logs2000 = logarithme du taux d'épargne en 2000
logn2000 = logarithme du taux de croissance de la population
         additionné du taux de croissance du progrès technique et
         du taux de dépréciation du stock de capital en 2000
logs = logarithme du taux d'épargne annuel moyen entre 1970 et 2000
logn = logarithme du taux de croissance annuel moyen de la population sur la période 1970-2000
        additionné du taux de croissance du progrès technique et du taux de
        dépréciation du stock de capital
*/

DISPLAY '*******************************************************'
DISPLAY "Problème n°1 : estimation de l'équation d'équilibre"
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

LINREG logy2000
# CONSTANT logs2000 logn2000
*estimation mco : les résultats sont donnés dans le tableau 1 du corrigé


DISPLAY 'QUESTION 2'

RESTRICT(CREATE) 1
# 2 3
# 1 1 0
*test la contrainte: le coefficient de logs2000 (la seconde variable)
*plus le coefficient de logn2000 (la troisième variable) égale à 0
*avec la statistique de Fisher, puis estime le modèle avec la contrainte



DISPLAY '*******************************************************'
DISPLAY "Problème n°2 : estimation de l'équation de convergence"
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

SET dlogy = logy2000-logy70
*calcul du taux de croissance du PIB par tête

SCAT(HLABEL='logy70',VLABEL='logy2000-logy70') 1
# logy70 dlogy
*représente (logy2000-logy70) en fonction de logy70

LINREG dlogy  / residu
# CONSTANT logy70
*estimation de l"équation de convergence absolue

DISPLAY 'vitesse annuelle' -log(1+%BETA(2))/31 ; *on divise par 31 car le taux de croissance du PIB est calculé sur une période de 31 années*
DISPLAY 'délai de retour à l"équilibre' log(0.5)/(log(1+%BETA(2))/31)
PRJ dlogyp
*calcul des valeurs estimées, la série est intitulée dlogyp

PRINT / residu

DISPLAY 'QUESTION 2'

LINREG dlogy
# CONSTANT logy70 dums dumd
*estimation de l"équation de convergence absolue par les MCO en incluant les variables indicatrices  dums et dumd

DISPLAY 'vitesse annuelle' -log(1+%BETA(2))/31 ; *on divise par 31 car le taux de croissance du PIB est calculé sur une période de 31 années*
DISPLAY 'délai de retour à l"équilibre' log(0.5)/(log(1+%BETA(2))/31)

DISPLAY 'QUESTION 3'

LINREG dlogy
# CONSTANT logy70 logs logn
RESTRICT(CREATE) 1
# 3 4
# 1 1 0
* estimation de l"équation de convergence conditionnelle et test d'égalité en valeur absolue des paramètres 3 et 4


DISPLAY 'vitesse annuelle' -log(1+%BETA(2))/31 ; *on divise par 31 car le taux de croissance du PIB est calculé sur une période de 31 années*
DISPLAY 'part du capital' (-%BETA(3)/%BETA(2))/(1+(-%BETA(3)/%BETA(2)))

LINREG dlogy
# CONSTANT logy70 logs logn
EXCLUDE
# logs logn
*test d'égalité à 0 des paramètres de logs et logn*



DISPLAY 'QUESTION 4'

LINREG dlogy
# CONSTANT logy70 logs logn dums dumd
RESTRICT(CREATE) 1
# 3 4
# 1 1 0
* estimation de l"équation de convergence conditionnelle augmentée et test d'égalité en valeur absolue des paramètres 3 et 4

DISPLAY 'vitesse annuelle' -log(1+%BETA(2))/31 ; *on divise par 31 car le taux de croissance du PIB est calculé sur une période de 31 années*
DISPLAY 'part du capital' (-%BETA(3)/%BETA(2))/(1+(-%BETA(3)/%BETA(2)))

PRJ dlogypdum
*calcul des valeurs estimées, la série est intitulée dlogypdum

GRAPH(NODATES,NUMBER=1,STYLE=SYMBOL,HEADER='Comparaison des valeurs estimées et observées de la variable dLogy',KEY=LORIGHT) 3
# DLogy
# DLogyp
# DLogypdum

COMPUTE dlogy1 = %beta(1)+%beta(2)*10+%beta(3)*3.15+%beta(4)*(-2.85)
disp dlogy1
*calcul de la valeur prédite lorsque Logy70=10, Logs=3.15, logn=-2.85, DMUS=0 et DUMD=0

DEC VECTOR X0(6)
COMPUTE X0 = || 1.0 | 10.0 | 3.15 | -2.85 | 0.0 | 0.0 ||
COMPUTE  e1 = tr(X0)*%XX*X0
COMPUTE e11 = %SCALAR(e1)
COMPUTE  ecarttype = SQRT(%SEESQ *(1.0+e11))
disp ecarttype
*calcul de l'écart-type de l'erreur de prévision

compute borneinf = dlogy1 - ecarttype * 2.069
compute bornesup = dlogy1 + ecarttype * 2.069
disp '********intervalle de confiance*************'
disp @10 "dlogy1"  @20 "borneinf" @30 "bornesup"
disp @10 ##.### dlogy1  @20 ##.### borneinf @30 ##.### bornesup

COMPUTE dlogy2 = %beta(1)+%beta(2)*10+%beta(3)*3.15+%beta(4)*(-2.85)+%beta(5)
disp dlogy2
*calcul de la valeur prédite lorsque Logy70=10, Logs=3.15, logn=-2.85, DMUS=1 et DUMD=0

DEC VECTOR X0(6)
COMPUTE X0 = || 1.0 | 10.0 | 3.15 | -2.85 | 1.0 | 0.0 ||
COMPUTE  e1 = tr(X0)*%XX*X0
COMPUTE e11 = %SCALAR(e1)
COMPUTE  ecarttype = SQRT(%SEESQ *(1.0+e11))
disp ecarttype
*calcul de l'écart-type de l'erreur de prévision

compute borneinf = dlogy2 - ecarttype * 2.069
compute bornesup = dlogy2 + ecarttype * 2.069
disp '********intervalle de confiance*************'
disp @10 "dlogy2"  @20 "borneinf" @30 "bornesup"
disp @10 ##.### dlogy2  @20 ##.### borneinf @30 ##.### bornesup


DISPLAY '*******************************************************'
DISPLAY 'Problème n°3 : analyse du processus de convergence'
DISPLAY	"avec introduction d'effets spécifiques pour les pays de l'UE"
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

PRINT / dumeu
*la  variable dumeu prend la valeur 1 pour les pays européens et 0 sinon*

SET dumeulogy70 = dumeu*logy70
LINREG dlogy
# CONSTANT logy70 logs logn dumeu dumeulogy70 dums dumd
*la variable dumeu introduit un effet spécifique aux pays de l"UE*

RESTRICT(CREATE) 1
# 3 4
# 1 1 0

DISPLAY 'QUESTION 2'

DISPLAY 'vitesse annuelle pays non UE' @40 ##.### -log(1+%BETA(2))/31
DISPLAY 'vitesse annuelle pays UE' @40 ##.###  -log(1+%BETA(2)+%beta(6))/31

DISPLAY 'Part du capital pays non UE' @40 ##.### (-%BETA(3)/%BETA(2))/(1+(-%BETA(3)/%BETA(2)))
DISPLAY 'Part du capital pays UE' @40 ##.### (-%BETA(3)/(%BETA(2)+%beta(6)))/(1+(-%BETA(3)/(%BETA(2)+%beta(6))))


OPEN COPY donnees_chap4.xls
COPY(FORMAT=XLS,ORG=COLS,DATES) / logy2000 logy70 dlogy dlogyp dlogypdum
*sauvegarde les données sous le format xls
*afin de réaliser les graphiques sous Excel