DISPLAY '*******************************************************'
DISPLAY 'LA RELATION SALAIRES-PRIX A LONG TERME'
DISPLAY '*******************************************************'

CALENDAR 1975 1 4
*précise la fréquence des données et l'année de départ
*données trimestrielles, départ 1975 premier trimestre

ALLOCATE 15 1995:4
*précise la longueur des séries et alloue un espace de 15 séries en mémoire

OPEN DATA chapitre17.xls
*ouverture du fichier de données chapitre16.xls

DATA(FORMAT=XLS,ORG=COLS) 1977:1 1995:4
*lecture des séries du fichier

PRINT /
*affichage des séries

*******************************************************
*                 Intitulé des séries                 *
*******************************************************

/*
sal = gains horaires perçus par les salariés de l'industrie manufacturière
defpib = déflateur du PIB
prod = production industrielle
emp = emploi industriel
cho = taux de chômage standardisé (en %)
*/

SET salr = (sal/defpib)
*construction de la série salr
*salr = salaire réel

SET w = log(salr)
*w = transformation logarithmique de la série salr

SET lprod = log(prod)
*lprod = transformation logarithmique de la série prod

SET lemp = log(emp)
*lemp = transformation logarithmique de la série emp

SET u = -log(1-cho/100)
*u = approximation du taux de chomage standardisé en %

SET lpop = lemp+u
*lpop = logarithme de l'approximation du plein emploi

SET y = lprod-lpop
*y =  logarithme de l'approximation de la productivité de plein emploi

DIFFERENCE w / dw
DIFFERENCE u / du
DIFFERENCE y / dy
*différenciation des séries

SET du83 = t==1983:01
*du83 = variable indicatrice=1 au premier trimestre 1983, =0 sinon

SET du80 = t>=1980:1.and.t<=1985:4
*du80 = variable indicatrice=1 du premier trimestre 1980 au dernier
*trimestre 1985, =0 sinon

SET du82 = t>=82:02.and.t<=1982:3
*du82 =variable indicatrice=1 les second et troisième trimestre 1982,
*=0 sinon

DISPLAY '*******************************************************'
DISPLAY "Problème n°1 : ordre d'intégration des séries"
DISPLAY '*******************************************************'

*Sélection du retard pour le test intégration:

SOURCE(NOECHO) lagselec.src
*compilation de la procédure lagselec.src

DOFOR series=w y u
DIS %label([series] series)
@LAGSELECT(maxlag=8,sclags=18,det=constant,signif=.05) series 1977:1 1995:4
END DO
*exécution de la procédure lagselec pour les séries w, y et u par la boucle DOFOR
*(terminée par END DO)
*résultats du tableau 1, tableau 2, tableau 3

*Tests de Dickey-Fuller augmentés :

SOURCE(NOECHO) urauto.src
@URAUTO(lag=1) w 1977:01 1995:4
@URAUTO(lag=2) u 1977:01 1995:4
@URAUTO(lag=1) y 1977:01 1995:4
@URAUTO(lag=1) dw 1977:02 1995:4
@URAUTO(lag=2) du 1977:02 1995:4
@URAUTO(lag=1) dy 1977:02 1995:4
*compilation et exécution de la procédure urauto.src
*résultats du tableau 4

DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : nombre de décalages du modèle VAR'
DISPLAY '*******************************************************'

DISP '***test d"un VAR à I retards contre un VAR à I+1 retards :***'

DO I = 1,5

DISPLAY 'Test H0 : I retards'
DISPLAY '     H1 : I+1 retards'

SYSTEM 1 to 3
VARIABLES w u y
LAGS 1 to I
DETERMINISTIC constant
END(SYSTEM)
ESTIMATE(NOPRINT,NOFTESTS,NOSIGMA) 1977:1 1995:4 1
*estimation d'un VAR à I retards
*sauvegarde des résidus dans les séries 1, 2 et 3

SYSTEM 1 to 3
VARIABLES w u y
LAGS 1 to (I+1)
DETERMINISTIC constant
END(SYSTEM)
ESTIMATE(NOPRINT,NOFTESTS,NOSIGMA) 1977:1 1995:4 4
*estimation d'un VAR à I+1 retards
*sauvegarde des résidus dans les séries 4,4 et 6

RATIO(DEGREES=9,MCORR=(3*(I+1)+1))
# 1 to 3
# 4 to 6
*réalisation du test du ratio de vraisemblance à partir des séries de résidus
END DO I
*résultats présentés dans le tableau 5


DISP '***Test d"un VAR à 2 retards contre un VAR à 5 retards :***'

DISPLAY 'Test H0 : 2 retards'
DISPLAY '     H1 : 5 retards'

SYSTEM 1 to 3
VARIABLES w u y
LAGS 1 to 2
DETERMINISTIC constant
END(SYSTEM)
ESTIMATE(NOPRINT,NOFTESTS,NOSIGMA) 1977:1 1995:4 1

SYSTEM 1 to 3
VARIABLES w u y
LAGS 1 to 5
DETERMINISTIC constant
END(SYSTEM)
ESTIMATE(NOPRINT,NOFTESTS,NOSIGMA) 1977:1 1995:4 4

RATIO(DEGREES=27,MCORR=16)
# 1 to 3
# 4 to 6
*réalisation du test du ratio de vraisemblance à partir des séries de résidus

DISP '***Analyse résiduelle :***'

SOURCE(NOECHO) catsmain.src
*compilation du programme CATS

@CATS(LAGS=2,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*exécution de la procédure CATS
*faire l"étude des résidus en choisissant l'option Residual Analysis dans cats
*résultats présentés dans le tableau 6
***Ne pas oublier de cliquer sur Cats / Quit Cats***

DISPLAY '***************************************************'
DISPLAY 'Problème n°3 : nombre de relations de cointégration'
DISPLAY '***************************************************'

DISP '***Nombre de relation de cointégration - constante restreinte dans l'espace cointégrant***'

SMPL 1977:1 1995:4
*réduction de la plage de données utilisée
@CATS(LAGS=2,TABLES,DETREND=cimean,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*résultats présentés dans le tableau 7
***Ne pas oublier de cliquer sur Cats / Quit Cats***

DISP '***Nombre de relation de cointégration - constante non contrainte***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,TABLES,DETREND=drift,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*résultats présentés dans le tableau 8
***Ne pas oublier de cliquer sur Cats / Quit Cats***

DISP '***Nombre de relation de cointégration - trend contraint dans l'espace cointégré***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,TABLES,DETREND=cidrift,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*résultats présentés dans le tableau 10
***Ne pas oublier de cliquer sur Cats / Quit Cats***

DISP '***Tests d"exclusion, de stationnarité et d"exogénéité faible***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,PROC=tsprop,DUM,DETREND=cidrift) 1977:1 1995:4
# w y u
# du82 du83 du80
*résultats présentés dans le tableau 11

DISPLAY '*******************************************************'
DISPLAY 'Problème n°4 : Contraintes linéaires sur les relations'
DISPLAY 'de cointégration'
DISPLAY '*******************************************************'

DISP '***Identification de WS-PS***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,TABLES,DETREND=cidrift,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*dans le menu cats choisir la rubrique Rank of PI, indiquez 2 relations de cointégration
*le logiciel demande à partir de quelle variable il faut normaliser : taper 1 à chaque fois
*résultats présentés dans le tableau 12 (identification de WS et PS - étape 1)

*choisir ensuite l'option Restrictions on each of the betavectors
*taper 1 puis remplir la matrice, faire store (premier vecteur), sauvegarder
*taper 1  puis remplir la matrice, faire store (second vecteur), sauvegarder
*normaliser en tapant 1
*résultats présentés dans le tableau 13 (restrictions permettant d'identifier le modèle - étape 2 de l'identification)

*choisir de nouveau l'option Restrictions on each of the betavectors
*taper 1 puis remplir la matrice, faire store (premier vecteur), sauvegarder
*taper 2  puis remplir la matrice, faire store (second vecteur), sauvegarder
*normaliser en tapant 1
*résultats présentés dans le tableau 14  (test de restriction des coefficients et estimation du modèle contraint)

***Ne pas oublier de cliquer sur Cats / Quit Cats***


DISPLAY '*******************************************************'
DISPLAY 'Problème n°5 : Construction d"un VECM partiel'
DISPLAY '*******************************************************'

DISP '***Test d"exogénéité faible***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,TABLES,DETREND=cidrift,DUM) 1977:1 1995:4
# w y u
# du82 du83 du80
*résultats présentés dans le tableau 10

*dans le menu cats choisir la rubrique Rank of PI, indiquez 2 relations de cointégration
*le logiciel demande à partir de quelle variable il faut normaliser : taper 1 à chaque fois
*résultats présentés dans le tableau 12

*choisir de nouveau l'option Restrictions on each of the betavectors
*taper 1 puis remplir la matrice, faire store (premier vecteur), sauvegarder
*taper 2  puis remplir la matrice, faire store (second vecteur), sauvegarder
*normaliser en tapant 1
*résultats présentés dans le tableau 14

*choisir l'option Restrictions on alpha du menu cats
*nombre de restrictions : tapez 1 puis remplir la matrice
*choisir current rest.
*normaliser en tapant 1
*résultats présentés dans le tableau 15
***Ne pas oublier de cliquer sur Cats / Quit Cats***

DISP '***Estimation du VECM partiel***'

SMPL 1977:1 1995:4
@CATS(LAGS=2,TABLES,DETREND=cidrift,EXO,DUM) 1977:1 1995:4
# w u
# y
# du80 du82 du83
*les exogènes sont toujours introduites avant les variables indicatrices
*dans le menu cats choisir la rubrique Rank of PI, indiquez 2 relations de cointégration
*le logiciel demande à partir de quelle variable il faut normaliser : taper 1 à chaque fois
*choisir de nouveau l'option Restrictions on each of the betavectors
*taper 1 puis remplir la matrice, faire store (premier vecteur)
*taper 2  puis remplir la matrice, faire store (second vecteur)
*normaliser en tapant 1
*résulats de l'équation (13.31) et de la matrice alpha

DISP '***Dynamique de court terme***'
*choisir l'option Short Run Matrices dans cats
*on obtient les matrices gamma0, gamma1 et phi

***Ne pas oublier de cliquer sur Cats / Quit Cats***


DISP '***Test de Wald sur le coefficient de U dans WS***'
COMPUTE waldstat=((2.426-2.2)/0.437)**2
CDF CHISQUARE waldstat 1