DISPLAY '*******************************************************'
DISPLAY 'MODELISATION D"UN EQUILIBRE DE MARCHE'
DISPLAY '*******************************************************'

CALENDAR 1961
*précise l'année de départ

ALLOCATE 1998:1
*Spécifie la date de la dernière entrée

OPEN DATA chapitre11.xls
*ouverture du fichier de données

DATA(FORMAT=XLS,ORG=COLS)
*description du fichier de données

PRINT /
*impression de toutes les séries du fichier

********************************************************
*           Intitulé des différentes séries            *
********************************************************

/*
q = production bovine
ctot = consommation totale
p = prix à la production du boeuf (francs constants 70)
pb = prix à la consommation du boeuf (fc 70)
w = prix des aliments du bétail (fc 80)
B = solde du commerce extérieur
s = niveau des stocks publics en fin d'année
pm = prix à la consommation du mouton (fc 80)
ipc =  indice des prix à la consommation finale (fc 70)
R = revenu disponible du revenu des ménages français (francs courants)
pop = niveau de population française au 1er janvier
*/

DISPLAY '*******************************************************'
DISPLAY 'Problème n°1 : Construction des variables'
DISPLAY 'et analyse descriptive'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

COMPUTE p90b = p(1990:1)
*p90b correspond à la valeur de l'indice de prix l'année 1990
SET p = p/p90b*100
*calcul l'indice de prix en base 1900, on divise la série de prix par le prix en 1990

COMPUTE w90b= w(1990:1)
SET w = w/w90b*100
COMPUTE pb90b = pb(1990:1)
SET pb90 = pb/pb90b*100
COMPUTE pm90b = pm(1990:1)
SET pm90 = pm/pm90b*100
COMPUTE ipc90b = ipc(1990:1)
SET ipc = ipc/ipc90b*100


DISPLAY 'QUESTION 2'

SET pb = pb90/ipc
*rapport du prix du boeuf a conso /prix a la consommation

SET pm = pm90/ipc
*rapport prix du mouton à la conso /prix a la consommation

SET C = ctot/pop
*consommation de viande bovine par tete

SET r = r*100/ipc/pop
*revenu disponible par tete en francs constants

SET pr = p/ipc
*rapport du prix du boeuf à la production /prix a la consommation

DISPLAY 'QUESTION 3'

SET eqc = ctot + B + (s - s{1})
PRINT / q eqc
*vérification de l'équation comptable

DISPLAY 'QUESTION 4'

GRAPH(KEY=upl,HEADER='Figure 1 : Evolution de la consommation totale et de la production') 2
# ctot
# q

GRAPH(KEY=upl, HEADER='Figure 2 :  Evolution des indices de prix à la consommation du bœuf et du mouton (base 1990)') 2
# pb90
# pm90


DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : estimation du modèle'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

SET d74 = an==1974
*creation de la dummy concernant le boycott de la viande de veau

EQUATION offre q
# CONSTANT p{1 to 3} q{1} w{1} d74
*Equation d'offre

EQUATION demande C
# CONSTANT pb pm r C{1}
*Equation de demande

EQUATION marge pb
# CONSTANT pr
*Equation de marge

EQUATION solde B
# CONSTANT s{1}
*Equation du commerce extérieur

DISPLAY 'QUESTION 3'

SMPL 1964:1 1995:1
*réduction de la plage de données

LINREG(EQUATION=offre)
*Estimation de l'offre par les MCO à partir de l'équation définie précédemment

COMPUTE denom=1-%NOBS*%SEESQ*%XX(5,5)
IF denom>0
   COMPUTE h=%rho*SQRT(%NOBS/denom)
ELSE
   COMPUTE h=0.0
END IF
CDF NORMAL h
*calcul du h de Durbin*

INSTRUMENTS CONSTANT p{1 to 3}  q{1} w{1} d74 c{1} pm r s s{1}
*pour les DMC et TMS les instruments sont donnés par les variables prédéterminées et exogènes du modèle

LINREG(EQUATION=demande,INST)
*Estimation de la demande par les DMC

LINREG(EQUATION=marge,INST)

LINREG(EQUATION=solde)

DISPLAY 'QUESTION 4'

SMPL 1964:1 1995:1
SUR(INSTRUMENTS) 4
# offre
# demande
# marge
# solde
*estimation des 4 équations par les TMC

FRML(EQUATION=offre) foffre
FRML(EQUATION=demande) fdemande
FRML(EQUATION=marge) fmarge
FRML(EQUATION=solde) fsolde
*écrit sous forme de formule les équations

DISPLAY '*******************************************************'
DISPLAY 'Problème n°3 : Qualité prédictive du modèle et'
DISPLAY 'exemples de simulation'
DISPLAY '*******************************************************'



FRML(IDENTITY) fequilibre s = q - ctot -B +s{1}
*réécriture de la formule d'équilibre de façon à ne faire
*apparaitre à gauche les variables endogènes que dans une
*seule équation (q est déjà expliquée dans l'équation d'offre)

DISPLAY 'QUESTION 1'

GROUP fmodel foffre>>q1 fdemande>>c1 fmarge>>pb1 $
             fsolde>>b1 fequilibre
*regroupement des équations de marché au sein d'un modèle

SMPL 1964:1 1998:1

STEPS(MODEL=fmodel)
*simulation statique du modèle

GRAPH(KEY=UPLEFT,PATTERNS) 2
# q
# q1

GRAPH(KEY=UPLEFT,PATTERNS) 2
# c
# c1

GRAPH(KEY=UPLEFT,PATTERNS) 2
# pb
# pb1

GRAPH(KEY=UPLEFT,PATTERNS) 2
# b
# b1

DISPLAY 'QUESTION 2'

GROUP fmodel2 foffre>>q2 fdemande>>c2  fmarge>>pb2 $
             fsolde>>b2  fequilibre

SMPL 1964:1 1998:1

FORECAST(MODEL=fmodel2)
*simulation dynamique du modèle

GRAPH(KEY=UPLEFT,PATTERNS) 2
# q
# q2

GRAPH(KEY=UPLEFT,PATTERNS) 2
# c
# c2

GRAPH(KEY=UPLEFT,PATTERNS) 2
# pb
# pb2

GRAPH(KEY=UPLEFT,PATTERNS) 2
# b
# b2

THEIL(SETUP,MODEL=fmodel2) 5 4 1995:1
*parametres (5 équations, 4 nbre d'itérations, date de fin des données historiques)

DO date=1985:1,1995:1
   THEIL date
END DO date
THEIL(DUMP)
*affichage des prévisions jusqu'à T+4 et du critère de Theil

DISPLAY 'QUESTION 3'

SET w = w*2
*multiplication du prix des aliments par 2

GROUP fmodel3 foffre>>q3 fdemande>>c3 fmarge>>pb3 $
               fsolde>>b3  fequilibre

STEPS(print,MODEL=fmodel3)

GRAPH(KEY=UPLEFT,PATTERNS) 2
# q
# q3