DISPLAY '*******************************************************'
DISPLAY 'MODELISATION D"UN SYSTEME DE DEMANDE DE FACTEURS'
DISPLAY 'DE PRODUCTION'
DISPLAY '*******************************************************'

CALENDAR 1978
*précise l'année de départ

ALLOCATE 1993:1
*Spécifie la date de la dernière entrée

OPEN DATA chapitre10.xls
*ouverture du fichier de données

DATA(FORMAT=XLS,ORG=COLS) / pv vent wci xci wk xk wl xl
*description du fichier de données

PRINT /
*impression de toutes les séries du fichier

********************************************************
*           Intitulé des différentes séries            *
********************************************************

/*
xl = quantité de travail
xk = quantité de capital
xci = quantité de consommations intermédiaires
wl = cout du travail
wk = cout du capital
wci = prix des consommations intermédiaires
pv = prix de l'output
vent = niveau des ventes de l'output
*/

DISPLAY '*******************************************************'
DISPLAY 'Problème n°1 : construction des variables et'
DISPLAY 'analyse descriptive'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

SET qy = vent/pv
*qy = niveau de production

COMPUTE wk80 = wk(1980:1)
SET wk = wk/wk80*100
COMPUTE wl80 = wl(1980:1)
SET wl = wl/wl80*100
*interprétation en francs constants 1980

DISPLAY 'QUESTION 2'

SET ct = wk*xk + wl*xl + wci*xci
*Calcul du coût total

SET sk = (wk*xk)/ct
SET sl = (wl*xl)/ct
SET sci = (wci*xci)/ct
SET soms = sk + sl + sci
STATISTICS soms
*Calcul des parts de dépense et vérification du calcul

DISPLAY 'QUESTION 3'

GRAPH(KEY=UPLEFT) 4
# pv
# wci
# wk
# wl
*graphique représentant l'évolution des prix

SET ik = xk / qy
SET il = xl / qy
SET ici = xci / qy
*Etude de l'intensivité de chaque facteur

GRAPH(OVERLAY=LINE,KEY=UPLEFT) 3
# il
# ici
# ik

DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : Estimation du système de parts'
DISPLAY 'de dépenses et interprétation des résultats'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

SET lwk = LOG(wk)
SET lwl = LOG(wl)
SET lwci = LOG(wci)
SET lwkci = LOG(wk/wci)
SET lwlci = LOG(wl/wci)
*Transformation des variables du système en logarithme lorsque
*l'on omet l'équation de la part des consommations intermédiaires

EQUATION esk sk
#CONSTANT lwlci lwkci
*Equation de part de dépense en facteur capital

EQUATION esl sl
#CONSTANT lwkci lwlci
*Equation de part de dépense en facteur travail

EQUATION esci sci
#CONSTANT lwkci lwlci
*Equation de part de dépense en consommations intermédiaires

DISPLAY 'QUESTION 2'

LINREG(EQUATION=esk)
*Estimation par les MCO de l'équation esk

LINREG(EQUATION=esl)

LINREG(EQUATION=esci)

DISPLAY 'QUESTION 3'

SUR 2 / EQUATE 2
# esk
# esl
*Estimation par la méthode de Zellner (SURE) non itérative en enlevant esci

COMPUTE ak = %BETA(2), akl =%BETA(1), akk = %BETA(3)
COMPUTE al = %BETA(4) , all = %BETA(5)
*Sauvegarde des coefficients de l'estimation

COMPUTE aci=1-ak-al
COMPUTE acik=-akl-akk
COMPUTE acil=-all-akl
COMPUTE acici=-acik-acil
*Déduction des coefficients de l'equation omise

SET lwlk = LOG(wl/wk)
SET lwcik = LOG(wci/wk)

EQUATION esl2 sl
#CONSTANT lwcik lwlk

EQUATION esci2 sci
#CONSTANT lwlk lwcik

SUR 2 / EQUATE 2
# esl2
# esci2
*Estimation par la méthode de Zellner (SURE) non itérative en enlevant esci

COMPUTE bl = %BETA(2), blci =%BETA(1), bll = %BETA(3)
COMPUTE bci = %BETA(4) , bcici = %BETA(5)
*Sauvegarde des coefficients de l'estimation

COMPUTE bk=1-bl-bci
COMPUTE bkl=-bll-blci
COMPUTE bkci=-blci-bcici
COMPUTE bkk=-bkl-bkci
*Déduction des coefficients de l'equation omise

DISPLAY 'ak   = ' ak  '   bk   = ' bk
DISPLAY 'akk  = ' akk '   bkk  = ' bkk
DISPLAY 'akl  = ' akl '   bkl  = ' bkl
DISPLAY 'akci = ' acik '   bkci = ' bkci

DISPLAY 'al   = ' al  '   bl   = ' bl
DISPLAY 'all  = ' all '   bll = ' bll
DISPLAY 'alci = ' acil '   blci = ' blci

DISPLAY 'aci  = ' aci '   bci  = ' bci
DISPLAY 'acici = ' acici '   bcici = ' bcici
*Compraison des coefficents selon l'équation omise

DISPLAY 'QUESTION 4'

SUR(iters=100) 2 / equate 2
# esk
# esl
*Methode Zellner Iterative : Estimation  du systeme en enlevant l'equation sci

COMPUTE ck = %BETA(2), ckl =%BETA(1), ckk = %BETA(3)
COMPUTE cl = %BETA(4) , cll = %BETA(5)
*Sauvegarde des coefficients de l'estimation

COMPUTE cci=1-ck-cl
COMPUTE ccik=-ckl-ckk
COMPUTE ccil=-cll-ckl
COMPUTE ccici=-ccik-ccil
*Déduction des coefficients de l'equation omise

SUR(iters=100) 2 / equate 2
# esl2
# esci2
*Methode Zellner Iterative : Estimation  du systeme en enlevant l'equation sk

COMPUTE dl = %BETA(2), dlci =%BETA(1), dll = %BETA(3)
COMPUTE dci = %BETA(4) ,dcici = %BETA(5)
*Sauvegarde des coefficients de l'estimation

COMPUTE dk=1-dl-dci
COMPUTE dkl=-dll-dlci
COMPUTE dkci=-dlci-dcici
COMPUTE dkk=-dkl-dkci
*Déduction des coefficients de l'equation omise

DISPLAY 'ck   = ' ck  '   dk   = ' dk
DISPLAY 'ckk  = ' ckk '   dkk  = ' dkk
DISPLAY 'ckl  = ' ckl '   dkl  = ' dkl
DISPLAY 'ckci = ' ccik '   dkci = ' dkci

DISPLAY 'cl   = ' cl  '   dl   = ' dl
DISPLAY 'cll  = ' cll '   dll = ' dll
DISPLAY 'clci = ' ccil '   dlci = ' dlci

DISPLAY 'cci  = ' cci '   dci  = ' dci
DISPLAY 'ccici =' ccici '   dcici =' dcici
*Compraison des coefficents selon l'équation omise


DISPLAY 'QUESTION 5'

SET skk = (ckk + sk*sk - sk)/(sk*sk)
SET sll = (cll + sl*sl - sl)/(sl*sl)
SET scici = (ccici + sci*sci - sci)/(sci*sci)
SET skl = (ckl + sk*sl) / (sk*sl)
SET skci = (ccik + sk*sci) / (sk*sci)
SET slci = (ccil + sl*sci) / (sl*sci)
*Calcul des elasticités partielles de substitution de Allen

PRINT / skk sll scici skl skci slci

SET nkk = (ckk + sk*sk-sk) / sk
SET nkl = sk*skl
SET nkci = sk*skci
SET nll = (cll + sl*sl -sl) / sl
SET nlk = sl*skl
SET nlci = sl*slci
SET ncici = (ccici + sci*sci -sci) / sci
SET ncik = sci*skci
SET ncil = sci*slci
*Calcul des elasticités Prix

PRINT / nkk nkl nkci
PRINT / nll nlk nlci
PRINT / ncici ncik ncil