wfcreate(wf="chapitre10") a 1978 1993

read(a2) h:\livre\chapitre10.xls 8

'Problème n°1 : construction des variables et anayse descriptive
'____________________________________________________

'QUESTION 1
'-------------------

genr qy = vent/pv
'qy = niveau de production

scalar wk80 = wk(@dtoo("1980"))
genr wk = wk/wk80*100
scalar wl80 = wl(@dtoo("1980"))
genr wl = wl/wl80*100
'interprétation en francs constants 1980

'QUESTION 2
'-------------------

genr ct = wk*xk + wl*xl + wci*xci
'Calcul du coût total

genr sk = (wk*xk)/ct
genr sl = (wl*xl)/ct
genr sci = (wci*xci)/ct
genr soms = sk + sl + sci
soms.stats
'Calcul des parts de dépense et vérification du calcul

'QUESTION 3
'-------------------

plot pv  wci  wk  wl
'graphique représentant l'évolution des prix

genr ik = xk / qy
genr il = xl / qy
genr ici = xci / qy
'Etude de l'intensivité de chaque facteur

line(x) ik il ici 

'Problème n°2 : Estimation du système de parts de dépenses et interprétation des résultats
'____________________________________________________

'Question 1
'---------------

genr lwk = LOG(wk)
genr lwl = LOG(wl)
genr lwci = LOG(wci)
genr lwkci = LOG(wk/wci)
genr lwlci = LOG(wl/wci)

'Question 2
'---------------

equation esk.ls sk c lwlci lwkci
'Equation de part de dépense en facteur capital

equation esl.ls sl c lwkci lwlci
'Equation de part de dépense en facteur travail

equation esci.ls sci c lwkci lwlci
'Equation de part de dépense en consommations intermédiaires

'Question 3
'---------------
system sys1
sys1.append sk=c(1)+c(2)*lwlci+c(3)*lwkci
sys1.append sl=c(4)+c(2)*lwkci+c(5)*lwlci
sys1.sur

scalar ak = sys1.c(1)
scalar akl =sys1.c(2)
scalar akk = sys1.c(3)
scalar al = sys1.c(4) 
scalar all = sys1.c(5)
'*Sauvegarde des coefficients de l'estimation

scalar aci=1-ak-al
scalar acik=-akk-akl
scalar acil=-all-akl
scalar acici=-acik-acil
'Déduction des coefficients de l'equation omise


genr lwlk=log(wl/wk)
genr lwcik=log(wci/wk)

system sys2
sys2.append sl=c(1)+c(2)*lwcik+c(3)*lwlk
sys2.append sci=c(4)+c(2)*lwlk+c(5)*lwcik
sys2.sur


scalar bl = sys2.c(1)
scalar blci =sys2.c(2)
scalar bll = sys2.c(3)
scalar bci = sys2.c(4) 
scalar bcici = sys2.c(5)
'*Sauvegarde des coefficients de l'estimation

scalar bk=1-bl-bci
scalar bkl=-bll-blci
scalar bkci=-blci-bcici
scalar bkk=-bkl-bkci
'Déduction des coefficients de l'equation omise


table(9,4) question3
question3(1,1)="ak"
question3(2,1)="akk"
question3(3,1)="akl"
question3(4,1)="akci"
question3(5,1)="al"
question3(6,1)="all"
question3(7,1)="alci"
question3(8,1)="aci"
question3(9,1)="acici"
question3(1,2)=ak
question3(2,2)=akk
question3(3,2)=akl
question3(4,2)=acik
question3(5,2)=al
question3(6,2)=all
question3(7,2)=acil
question3(8,2)=aci
question3(9,2)=acici
question3(1,3)="bk"
question3(2,3)="bkk"
question3(3,3)="bkl"
question3(4,3)="bkci"
question3(5,3)="bl"
question3(6,3)="bll"
question3(7,3)="blci"
question3(8,3)="bci"
question3(9,3)="bcici"
question3(1,4)=bk
question3(2,4)=bkk
question3(3,4)=bkl
question3(4,4)=bkci
question3(5,4)=bl
question3(6,4)=bll
question3(7,4)=blci
question3(8,4)=bci
question3(9,4)=bcici

'Question 4
'---------------
system sys3
sys3.append sk=c(1)+c(2)*lwlci+c(3)*lwkci
sys3.append sl=c(4)+c(2)*lwkci+c(5)*lwlci
sys3.sur(i)
scalar ck = sys3.c(1)
scalar ckl =sys3.c(2)
scalar ckk = sys3.c(3)
scalar cl = sys3.c(4) 
scalar cll = sys3.c(5)
'*Sauvegarde des coefficients de l'estimation

scalar cci=1-ck-cl
scalar ccik=-ckk-ckl
scalar ccil=-cll-ckl
scalar ccici=-ccik-ccil
'Déduction des coefficients de l'equation omise

system sys4
sys4.append sl=c(1)+c(2)*lwcik+c(3)*lwlk
sys4.append sci=c(4)+c(2)*lwlk+c(5)*lwcik
sys4.sur(i)


scalar dl = sys4.c(1)
scalar dlci =sys4.c(2)
scalar dll = sys4.c(3)
scalar dci = sys4.c(4) 
scalar dcici = sys4.c(5)
'*Sauvegarde des coefficients de l'estimation

scalar dk=1-dl-dci
scalar dkl=-dll-dlci
scalar dkci=-dlci-dcici
scalar dkk=-dkl-dkci
'Déduction des coefficients de l'equation omise

table(9,4) question4
question4(1,1)="ck"
question4(2,1)="ckk"
question4(3,1)="ckl"
question4(4,1)="ckci"
question4(5,1)="cl"
question4(6,1)="cll"
question4(7,1)="clci"
question4(8,1)="cci"
question4(9,1)="ccici"
question4(1,2)=ck
question4(2,2)=ckk
question4(3,2)=ckl
question4(4,2)=ccik
question4(5,2)=cl
question4(6,2)=cll
question4(7,2)=ccil
question4(8,2)=cci
question4(9,2)=ccici
question4(1,3)="dk"
question4(2,3)="dkk"
question4(3,3)="dkl"
question4(4,3)="dkci"
question4(5,3)="dl"
question4(6,3)="dll"
question4(7,3)="dlci"
question4(8,3)="dci"
question4(9,3)="dcici"
question4(1,4)=dk
question4(2,4)=dkk
question4(3,4)=dkl
question4(4,4)=dkci
question4(5,4)=dl
question4(6,4)=dll
question4(7,4)=dlci
question4(8,4)=dci
question4(9,4)=dcici

'Question 5
'---------------


GENR skk = (ckk + sk*sk - sk)/(sk*sk)
GENR sll = (cll + sl*sl - sl)/(sl*sl)
GENR scici = (ccici + sci*sci - sci)/(sci*sci)
GENR skl = (ckl + sk*sl) / (sk*sl)
GENR skci = (ccik + sk*sci) / (sk*sci)
GENR slci = (ccil + sl*sci) / (sl*sci)
'*Calcul des elasticités partielles de substitution de Allen


GENR nkk = (ckk + sk*sk-sk) / sk
GENR nkl = sk*skl
GENR nkci = sk*skci
GENR nll = (cll + sl*sl -sl) / sl
GENR nlk = sl*skl
GENR nlci = sl*slci
GENR ncici = (ccici + sci*sci -sci) / sci
GENR ncik = sci*skci
GENR ncil = sci*slci
'*Calcul des elasticités Prix