wfcreate(wf="chapitre5", page="page1") q 1/1/1970 31/12/1998

read(a2,s=bl) h:\livre\exam\chapitre05.xls 63


'Probleme 1 : Evaluation par simulation
'________________________________

!j=1
for %i fr dm nl es it uk

'Question 1
'----------------

genr pibga_{%i}=100*(pib_{%i}-pib_{%i}(-4))/pib_{%i}(-4)
genr cpiga_{%i}=100*(cpi_{%i}-cpi_{%i}(-4))/cpi_{%i}(-4)
genr ecinf_{%i}=cpiga_{%i}-2
pib_{%i}.hpf(lambda=1600) hp_{%i}
genr hpga_{%i}=100*(hp_{%i}-hp_{%i}(-4))/hp_{%i}(-4)
genr gap_{%i}=100*(pib_{%i}-hp_{%i})/hp_{%i}
'plot pib_{%i} hp_{%i}
'plot pibga_{%i} hpga_{%i}
'plot gap_{%i} cpiga_{%i}

'Question 2
'----------------

genr ts_{%i}=hpga_{%i}+cpiga_{%i}+0.5*ecinf_{%i}+0.5*gap_{%i}
genr tn_{%i}=hpga_{%i}+cpiga_{%i}
'plot tc_{%i} tn_{%i} ts_{%i}

'Question 3
'----------------

genr ec_{%i}=tc_{%i}-tn_{%i}
genr ec2_{%i}=(ec_{%i})^2
genr er_{%i}=tc_{%i}-ts_{%i}
genr er2_{%i}=(er_{%i})^2

%fin="1995q4"

matrix(@dtoo(%fin)+1,6) rmsec
matrix(@dtoo(%fin)+1,6) rmsee

!i=1

for !step=0 to @dtoo(%fin)
smpl 01/01/1970+!step 01/01/1970+!step+11
if @sum(ec2_{%i})=na then
rmsec(!i,!j)=na
else
rmsec(!i,!j)=@sqrt(@mean(ec2_{%i}))
endif
if @sum(er2_{%i})=na then
rmsee(!i,!j)=na
else
rmsee(!i,!j)=@sqrt(@mean(er2_{%i}))
endif
!i=!i+1
next
!j=!j+1
smpl @all
next

store rmsec rmsee

pagecreate(page="rmse") q 1973q1 1999q1
fetch rmsec rmsee
group group1
group group2
for %i fr dm nl es it uk
series rmsec_{%i}
series rmsee_{%i}
group1.add rmsec_{%i}
group2.add rmsee_{%i}
next
mtos(rmsec,group1)
mtos(rmsee,group2)
plot rmsec_fr rmsec_dm rmsec_nl rmsec_es rmsec_it rmsec_uk
plot rmsee_fr rmsee_dm rmsee_nl rmsee_es rmsee_it rmsee_uk

pageselect page1
'stop

'Probleme 2 : Evaluation par estimation et tests sur longue periode
'______________________________________________________

smpl @all

table(21,7) tableau1
tableau1(2,1)="Ec. type reg"
tableau1(3,1)="DW"
tableau1(4,1)="Fischer"
tableau1(5,1)="Signif"
tableau1(6,1)="ALPHA"
tableau1(7,1)="T-stat"
tableau1(8,1)="Lambda 1"
tableau1(9,1)="Ec-Type lambda1"
tableau1(10,1)="T-stat (lambda 1=0)"
tableau1(11,1)="Signif"
tableau1(12,1)="T-stat (lambda 1=0.5)"
tableau1(13,1)="Signif"
tableau1(14,1)="Lambda 2"
tableau1(15,1)="Ec-Type lambda2"
tableau1(16,1)="T-stat (lambda 2=0)"
tableau1(17,1)="Signif"
tableau1(18,1)="T-stat (lambda 2=0.5)"
tableau1(19,1)="Signif"
tableau1(20,1)="Fischer"
tableau1(21,1)="F-Signif"

!i=1
for %i fr dm nl es it uk

'Question 1
'---------------
equation eq_{%i}.ls ec_{%i} c ecinf_{%i} gap_{%i}
eq_{%i}.fit ecs_{%i}
genr te_{%i}=ecs_{%i}+tn_{%i}
plot tc_{%i} ts_{%i} te_{%i}

'Question 4
'----------------
equation eqcons_{%i}.ls ec_{%i}=c(1)+0.5*ecinf_{%i}+0.5*gap_{%i}
setcell(tableau1,1,!i+1,%i,"c")
setcell(tableau1,2,!i+1,eq_{%i}.@se,"c",2)
setcell(tableau1,3,!i+1,eq_{%i}.@dw,"c",2)
setcell(tableau1,4,!i+1,eq_{%i}.@f,"c",2)
setcell(tableau1,5,!i+1,@fdist(eq_{%i}.@f,eq_{%i}.@ncoef-1,eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)
setcell(tableau1,6,!i+1,eq_{%i}.c(1),"c",2)
setcell(tableau1,7,!i+1,eq_{%i}.@tstat(1),"c",2)
setcell(tableau1,8,!i+1,eq_{%i}.c(2),"c",2)
setcell(tableau1,9,!i+1,eq_{%i}.@stderrs(2),"c",2)
setcell(tableau1,10,!i+1,eq_{%i}.@tstat(2),"c",2)
setcell(tableau1,11,!i+1,@tdist(eq_{%i}.@tstat(2),eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)
setcell(tableau1,12,!i+1,(eq_{%i}.c(2)-0.5)/eq_{%i}.@stderrs(2),"c",2)
setcell(tableau1,13,!i+1,@tdist((eq_{%i}.c(2)-0.5)/eq_{%i}.@stderrs(2),eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)
setcell(tableau1,14,!i+1,eq_{%i}.c(3),"c",2)
setcell(tableau1,15,!i+1,eq_{%i}.@stderrs(3),"c",2)
setcell(tableau1,16,!i+1,eq_{%i}.@tstat(3),"c",2)
setcell(tableau1,17,!i+1,@tdist(eq_{%i}.@tstat(3),eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)
setcell(tableau1,18,!i+1,(eq_{%i}.c(3)-0.5)/eq_{%i}.@stderrs(3),"c",2)
setcell(tableau1,19,!i+1,@tdist((eq_{%i}.c(3)-0.5)/eq_{%i}.@stderrs(3),eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)
setcell(tableau1,20,!i+1,((eqcons_{%i}.@ssr-eq_{%i}.@ssr)/(eq_{%i}.@ncoef-1))/(eq_{%i}.@ssr/(eq_{%i}.@regobs-eq_{%i}.@ncoef)),"c",2)
setcell(tableau1,21,!i+1,@fdist(((eqcons_{%i}.@ssr-eq_{%i}.@ssr)/(eq_{%i}.@ncoef-1))/(eq_{%i}.@ssr/(eq_{%i}.@regobs-eq_{%i}.@ncoef)),eq_{%i}.@ncoef-1,eq_{%i}.@regobs-eq_{%i}.@ncoef),"c",2)

!i=!i+1
next
tableau1.table


'Probleme 3 : Analyse de la stabilité
'_____________________________

'Question 1
'---------------

sample smpl7079 1970q1 1979q4
sample smpl8089 1980q1 1989q4
sample smpl8898 1988q1 1998q3
sample smpl9098 1990q1 1998q3

for %t 7079 8089 8898 9098
smpl smpl{%t}

table(11,7) periode_{%t}

!i=1
for %i fr dm nl es it uk

equation eq_{%i}_{%t}.ls ec_{%i} c ecinf_{%i} gap_{%i}
equation eqcons_{%i}_{%t}.ls ec_{%i}=c(1)+0.5*ecinf_{%i}+0.5*gap_{%i}
freeze(wald_{%i}_{%t}) eq_{%i}_{%t}.wald c(2)=c(3)=0.5
periode_{%t}(2,1)="Ec. type reg"
periode_{%t}(3,1)="ALPHA"
periode_{%t}(4,1)="T-stat"
periode_{%t}(5,1)="Lambda 1"
periode_{%t}(6,1)="T-stat"
periode_{%t}(7,1)="T-stat (lambda 1=0.5)"
periode_{%t}(8,1)="Lambda 2"
periode_{%t}(9,1)="T-stat"
periode_{%t}(10,1)="T-stat (lambda 2=0.5)"
periode_{%t}(11,1)="F-signif"

setcell(periode_{%t},1,!i+1,%i,"c")
setcell(periode_{%t},2,!i+1,eq_{%i}_{%t}.@se,"c",2)
setcell(periode_{%t},3,!i+1,eq_{%i}_{%t}.c(1),"c",2)
setcell(periode_{%t},4,!i+1,eq_{%i}_{%t}.@tstat(1),"c",2)
setcell(periode_{%t},5,!i+1,eq_{%i}_{%t}.c(2),"c",2)
setcell(periode_{%t},6,!i+1,eq_{%i}_{%t}.@tstat(2),"c",2)
setcell(periode_{%t},7,!i+1,(eq_{%i}_{%t}.c(2)-0.5)/eq_{%i}_{%t}.@stderrs(2),"c",2)
setcell(periode_{%t},8,!i+1,eq_{%i}_{%t}.c(3),"c",2)
setcell(periode_{%t},9,!i+1,eq_{%i}_{%t}.@tstat(3),"c",2)
setcell(periode_{%t},10,!i+1,(eq_{%i}_{%t}.c(3)-0.5)/eq_{%i}_{%t}.@stderrs(3),"c",2)
setcell(periode_{%t},11,!i+1,@fdist(((eqcons_{%i}_{%t}.@ssr-eq_{%i}_{%t}.@ssr)/2)/(eq_{%i}_{%t}.@ssr/(eq_{%i}_{%t}.@regobs-eq_{%i}_{%t}.@ncoef)),eq_{%i}_{%t}.@ncoef-1,eq_{%i}_{%t}.@regobs-eq_{%i}_{%t}.@ncoef),"c",2)
!i=!i+1
next
periode_{%t}.table
next



'Question 2
'----------------

'Test du CUSUM

for %i fr dm nl es it uk
eq_{%i}.rls(q)
next

'Estimation glissante des Lambda

matrix(76,6) lambda1
matrix(76,6) ectyplambda1
matrix(76,6) lambda2
matrix(76,6) ectyplambda2

!i=1
for !step=0 to 75

smpl 01/01/1970+!step 31/12/1979+!step
!j=1 
for %i fr dm nl es it uk
equation gliss_{%i}.ls ec_{%i} c ecinf_{%i} gap_{%i}
lambda1(!i,!j)=gliss_{%i}.c(2)
lambda2(!i,!j)=gliss_{%i}.c(3)
ectyplambda1(!i,!j)=gliss_{%i}.@stderrs(2)
ectyplambda2(!i,!j)=gliss_{%i}.@stderrs(3)
!j=!j+1
next
!i=!i+1
next

store lambda1 lambda2 ectyplambda1 ectyplambda2
smpl @all

pagecreate(page="estim_glissante") q 01/01/1970 31/12/1988
fetch lambda1 lambda2 ectyplambda1 ectyplambda2
group group1
group group2
group group3
group group4

for %i fr dm nl es it uk
series lambda1_{%i}
series lambda2_{%i}
series ectyplambda1_{%i}
series ectyplambda2_{%i}
group1.add lambda1_{%i}
group2.add lambda2_{%i}
group3.add ectyplambda1_{%i}
group4.add ectyplambda2_{%i}
next
mtos(lambda1,group1)
mtos(lambda2,group2)
mtos(ectyplambda1,group3)
mtos(ectyplambda2,group4)

for %i fr dm nl es it uk
genr min1_{%i}=lambda1_{%i}-2*ectyplambda1_{%i}
genr sup1_{%i}=lambda1_{%i}+2*ectyplambda1_{%i}
genr min2_{%i}=lambda2_{%i}-2*ectyplambda2_{%i}
genr sup2_{%i}=lambda2_{%i}+2*ectyplambda2_{%i}
plot lambda1_{%i} min1_{%i} sup1_{%i}
plot lambda2_{%i} min2_{%i} sup2_{%i}
next