wfcreate(wf="chapitre4") u 28
read(b2,s=chapitre4) h:\Livre\chapitre4.xls 9

'Problème n°1 : estimation de l'équation d'équilibre
'_________________________________________

'Question 1
'---------------

equation eq1.ls logy2000 c logs2000 logn2000

'Question 2
'---------------
equation eq1cons.ls logy2000=c(1)+c(2)*logs2000-c(2)*logn2000

scalar ftest_12=((eq1cons.@ssr-eq1.@ssr)/1)/(eq1.@ssr/25)
scalar pval_12=@fdist(ftest_12,1,25)


'Problème n°2 : estimation de l'équation de convergence
'_____________________________________________

'Question 1
'---------------

genr dlogy=logy2000-logy70

'scat logy70 dlogy

equation eq2.ls dlogy c logy70
genr residu=resid
scalar va_21=-(log(1+eq2.@coef(2))/31)
scalar dr_21=log(0.5)/(log(1+eq2.@coef(2))/31)
fit dlogyp

'Question 2
'---------------

equation eq22.ls dlogy c logy70 dums dumd
scalar va_22=-(log(1+eq22.@coef(2))/31)
scalar dr_22=log(0.5)/(log(1+eq22.@coef(2))/31)

'Question 3
'---------------

equation eq23.ls dlogy c logy70 logs logn
equation eq23cons.ls dlogy=c(1)+c(2)*logy70+c(3)*logs-c(3)*logn
scalar ftest_23=((eq23cons.@ssr-eq23.@ssr)/1)/(eq23.@ssr/24)
scalar pval_23=@fdist(ftest_23,1,24)
scalar va_23=-(log(1+eq23cons.@coef(2))/31)
scalar partcap_23=(-eq23cons.@coef(3)/eq23cons.@coef(2))/(1+(-eq23cons.@coef(3)/eq23cons.@coef(2)))
freeze(wald_23) eq23.wald c(3)=c(4)=0

'Question 4
'---------------
equation eq24.ls dlogy c logy70 logs logn dums dumd 
equation eq24cons.ls dlogy=c(1)+c(2)*logy70+c(3)*logs-c(3)*logn+c(4)*dums+c(5)*dumd
scalar ftest_24=((eq24cons.@ssr-eq24.@ssr)/1)/(eq24.@ssr/22)
scalar pval_24=@fdist(ftest_24,1,22)
scalar va_24=-(log(1+eq24cons.@coef(2))/31)
scalar partcap_24=(-eq24cons.@coef(3)/eq24cons.@coef(2))/(1+(-eq24cons.@coef(3)/eq24cons.@coef(2)))
fit dlogypdum
plot dlogy dlogyp dlogypdum

'c)

scalar dlogy1=c(1)+c(2)*10+c(3)*3.15-c(3)*(-2.85)
group group1 c logy70 logs logn dums dumd
matrix(28,1) x
stom(group1,x)
matrix(6,1) xo
xo.fill 1.0, 10.0, 3.15, -2.85, 0.0, 0.0

matrix e1=@transpose(xo)*@inverse(@transpose(x)*x)*xo
scalar e1b=e1(1,1)
scalar ecarttype=@sqrt(eq24cons.@se^2*(1+e1b))
scalar borneinf=dlogy1-ecarttype*2.069
scalar bornesup=dlogy1+ecarttype*2.069

'd)
scalar dlogy2=c(1)+c(2)*10+c(3)*3.15-c(3)*(-2.85)+c(4)
matrix(6,1) xo_d
xo_d.fill 1.0, 10.0, 3.15, -2.85, 1.0, 0.0

matrix e1_d=@transpose(xo_d)*@inverse(@transpose(x)*x)*xo_d
scalar e1b_d=e1_d(1,1)
scalar ecarttype_d=@sqrt(eq24cons.@se^2*(1+e1b_d))
scalar borneinf_d=dlogy2-ecarttype_d*2.069
scalar bornesup_d=dlogy2+ecarttype_d*2.069



'Problème n°3 : Analyse du processus de convergence avec introduction d'effets spécifiques pour les pays de l'UE
'_____________________________________________________________________________________________

'Question 1
'---------------

genr dumeulogy70=dumeu*logy70
equation eq31.ls dlogy c logy70 logs logn dumeu dumeulogy70 dums dumd
equation eq31cons.ls dlogy=c(1)+c(2)*logy70+c(3)*logs-c(3)*logn+c(4)*dumeu+c(5)*dumeulogy70+c(6)*dums+c(7)*dumd
scalar ftest_31=((eq31cons.@ssr-eq31.@ssr)/1)/(eq31.@ssr/20)
scalar pval_31=@fdist(ftest_31,1,20)


'Question 2
'---------------
scalar va_32_UE=-(log(1+eq31cons.@coef(2)+eq31cons.@coef(5))/31)
scalar va_32_nonUE=-(log(1+eq31cons.@coef(2))/31)

scalar partcap_32_nonUE=(-eq31cons.@coef(3)/eq31cons.@coef(2))/(1+(-eq31cons.@coef(3)/eq31cons.@coef(2)))
scalar partcap_32_UE=(-eq31cons.@coef(3)/(eq31cons.@coef(2)+eq31cons.@coef(5)))/(1+(-eq31cons.@coef(3)/(eq31cons.@coef(2)+eq31cons.@coef(5))))
stop