' txi7098 = investissement dans le PIB: part en moyenne annuelle 1970-1998
' txi7079 = investissement dans le PIB: part en moyenne annuelle 1970-' 1979
' txi8089 = investissement dans le PIB: part en moyenne annuelle 1980-1989
' txi9098 = investissement dans le PIB: part en moyenne annuelle 1990-1998
' txi7074 = investissement dans le PIB: part en moyenne annuelle 1970-1974
' txs7098 = taux d'épargne nationale: part en moyenne annuelle 1970-1998
' txs7079 = taux d'épargne nationale: part en moyenne annuelle 1970-1979
' txs8089 = taux d'épargne nationale: part en moyenne annuelle 1980-1989
' txs9098 = taux d'épargne nationale: part en moyenne annuelle 1990-1998
' txs7074 = taux d'épargne nationale: part en moyenne annuelle 1970-1974
' txsprive7098 = taux d'épargne privée: part en moyenne annuelle 1970-1998
' txsprive7079 = taux d'épargne privée: part en moyenne annuelle 1970-1979
' txsprive8089 = taux d'épargne privée: part en moyenne annuelle 1980-1989
' txsprive9098 = taux d'épargne privée: part en moyenne annuelle 1990-1998
' txsprive7074 = taux d'épargne privée: part en moyenne annuelle 1970-1974
' txspub7098 = taux d'épargne publique:  part en moyenne annuelle 1970-1998
' txspub7079 = taux d'épargne publique: part en moyenne annuelle 1970-1979
' txspub8089 = taux d'épargne publique: part en moyenne annuelle 1980-1989
' txspub9098 = taux d'épargne publique: part en moyenne annuelle 1990-1998
' txspub7074 = taux d'épargne publique: part en moyenne annuelle 1970-1974
' dc7098 = déficit commercial sur PIB:part en moyenne annuelle 1970-1998


wfcreate(wf="chapitre2") u 19

read(a2,s=chapitre2) h:\livre\chapitre02.xls 21


'Problème 1 : estimation du modèle feldstein et Horioka
'______________________________________________

'Estimation du modèle sur toutes les périodes
table(6,5) resultat1
resultat1(1,1)="PERIODE"
resultat1(1,2)="BETA"
resultat1(1,3)="TSTAT"
resultat1(1,4)="R2"
resultat1(1,5)="DW"

!i=1
for %t 7098 7079 8089 9098 7074

'Question 1, 4 et 5
'-------------------------
equation eq{%t}.ls txi{%t} c txs{%t}
setcell(resultat1,!i+1,1,%t,"c")
setcell(resultat1,!i+1,2,eq{%t}.c(2),"c")
setcell(resultat1,!i+1,3,eq{%t}.@tstat(2),"c")
setcell(resultat1,!i+1,4,eq{%t}.@r2,"c")
setcell(resultat1,!i+1,5,eq{%t}.@dw,"c")

if %t="7098" then
fit esti7098
scat txs7098 txi7098
scat txs7098 esti7098
endif

'Question 3
'---------------
freeze(wald{%t}) eq{%t}.wald c(2)=1
!i=!i+1
next


'Question 2
'---------------
smpl 1 15
equation eq15pays.ls txi7098 c txs7098
fit esti15
smpl @all




'Problème 2 : Extension du modèle initial avec prise en compte de la structure de l'épargne
'________________________________________________________

'Question 1
'---------------

table(5,7) resultat2
resultat2(1,1)="PERIODE"
resultat2(1,2)="BETAPRIVE"
resultat2(1,3)="TSTATPRIVE"
resultat2(1,4)="BETAPUB"
resultat2(1,5)="TSTATPUB"
resultat2(1,6)="R2"
resultat2(1,7)="DW"

!i=1
for %t 7098 7079 8089 9098
equation eq2{%t}.ls txi{%t} c txsprive{%t} txspub{%t}
setcell(resultat2,!i+1,1,%t,"c")
setcell(resultat2,!i+1,2,eq2{%t}.c(2),"c")
setcell(resultat2,!i+1,3,eq2{%t}.@tstat(2),"c")
setcell(resultat2,!i+1,4,eq2{%t}.c(3),"c")
setcell(resultat2,!i+1,5,eq2{%t}.@tstat(3),"c")
setcell(resultat2,!i+1,6,eq2{%t}.@r2,"c")
setcell(resultat2,!i+1,7,eq2{%t}.@dw,"c")
freeze(wald2{%t}) eq2{%t}.wald c(2)=c(3)
!i=!i+1
next

'Question 2
'---------------

equation eqres1.ls txi9098 c txsprive9098
series res1=resid

equation eqres2.ls txspub9098 c txsprive9098
series res2=resid

equation eqres.ls res1 c res2


'Problème 3 : Test du degré de mobilité des capitaux et de déficit commercial
'_____________________________________________________

'Question 1
'---------------

equation eqdc1.ls dc7098 c txs7098

'Question 2
'---------------

equation eqdc2.ls dc7098 c txsprive7098 txspub7098
freeze(waldmc) eqdc2.wald c(2)=c(3)

-

equation eqdc1.ls dc7098 c txs7098

'Question 2
'---------------

equation eqdc2.ls dc7098 c txsprive7098 txspub7098
freeze(waldmc) eqdc2.wald c(2)=c(3)