DISPLAY '*******************************************************'
DISPLAY 'MODELISATION DE LA RELATION EPARGNE INVESTISSEMENT'
DISPLAY '*******************************************************'

ALLOCATE 19
*alloue l'espace nécessaire aux données

OPEN DATA chapitre2.xls
*ouverture du fichier de données

DATA(FORMAT=XLS,ORG=COLS)
*description du fichier de données

PRINT /
*impression de toutes les séries du fichier

*******************************************************
*                 Intitulé des séries                 *
*******************************************************

/*
txi7098 = investissement dans le PIB: part en moyenne annuelle 1970-1998
txi7079 = investissement dans le PIB: part en moyenne annuelle 1970-1979
txi8089 = investissement dans le PIB: part en moyenne annuelle 1980-1989
txi9098 = investissement dans le PIB: part en moyenne annuelle 1990-1998
txi7074 = investissement dans le PIB: part en moyenne annuelle 1970-1974
txs7098 = taux d'épargne nationale: part en moyenne annuelle 1970-1998
txs7079 = taux d'épargne nationale: part en moyenne annuelle 1970-1979
txs8089 = taux d'épargne nationale: part en moyenne annuelle 1980-1989
txs9098 = taux d'épargne nationale: part en moyenne annuelle 1990-1998
txs7074 = taux d'épargne nationale: part en moyenne annuelle 1970-1974
txsprive7098 = taux d'épargne privée: part en moyenne annuelle 1970-1998
txsprive7079 = taux d'épargne privée: part en moyenne annuelle 1970-1979
txsprive8089 = taux d'épargne privée: part en moyenne annuelle 1980-1989
txsprive9098 = taux d'épargne privée: part en moyenne annuelle 1990-1998
txsprive7074 = taux d'épargne privée: part en moyenne annuelle 1970-1974
txspub7098 = taux d'épargne publique:  part en moyenne annuelle 1970-1998
txspub7079 = taux d'épargne publique: part en moyenne annuelle 1970-1979
txspub8089 = taux d'épargne publique: part en moyenne annuelle 1980-1989
txspub9098 = taux d'épargne publique: part en moyenne annuelle 1990-1998
txspub7074 = taux d'épargne publique: part en moyenne annuelle 1970-1974
dc7098 = déficit commercial sur PIB:part en moyenne annuelle 1970-1998
*/

DISPLAY '*******************************************************'
DISPLAY 'Problème n°1 : estimation du modèle de Feldstein'
DISPLAY 'et Horioka'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

LINREG txi7098
# CONSTANT txs7098
*estimation mco

PRJ esti7098
*calcul des valeurs estimées de i7098, la série de ces valeurs
*est appelée esti7098

SCAT(STYLE=SYMBOL,HEADER='relation épargne investissement',$
HLABEL='S/Y moyen', VLABEL='I/Y moyen') 2
# txs7098 txi7098
# txs7098 esti7098
*en fonction de la série s7098 on représente d'une part
*la série txi7098 et d'autre part la série esti7098


DISPLAY 'QUESTION 2'

LINREG txi7098 1 15
# constant txs7098
*estimation avec 15 observations au lieu de 19

PRJ esti15
*calcul des valeur estimées, la série est initulée esti15

DISPLAY 'QUESTION 4'

LINREG txi7079
# CONSTANT txs7079
*estimation sur la sous-période 70-79

LINREG txi8089
# CONSTANT txs8089
*estimation sur la sous-période 80-89

LINREG txi9098
# CONSTANT txs9098
*estimation sur la sous-période 90-98

DISPLAY 'QUESTION 5'

LINREG txi7074
# CONSTANT txs7074
*estimation sur la sous-période 70-74

DISPLAY '*******************************************************'
DISPLAY 'Problème n°2 : extension du modèle initial avec la '
DISPLAY "prise en compte de la structure de l'épargne"
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

*estimation sur l'ensemble de la période  :

LINREG txi7098
# CONSTANT txsprive7098 txspub7098
RESTRICT(CREATE) 1
# 2 3
# 1 -1 0
*test la contrainte: le coefficient de txsprive7098 (la seconde variable)
*moins le coefficient de txspub7098 (la troisième variable) égal à 0
*avec la statistique de Fisher, puis estime le modèle avec la contrainte


*estimation sur les sous-périodes :

LINREG txi7079
# CONSTANT txsprive7079 txspub7079
RESTRICT(CREATE) 1
# 2 3
# 1 -1 0

LINREG txi8089
# CONSTANT txsprive8089 txspub8089
RESTRICT(CREATE) 1
# 2 3
# 1 -1 0

LINREG txi9098
# CONSTANT txsprive9098 txspub9098
RESTRICT(CREATE) 1
# 2 3
# 1 -1 0

DISPLAY 'QUESTION 2'

LINREG txi9098 / res1
# CONSTANT txsprive9098
*estimation et sauvegarde de la série des résidus sous le nom res1

LINREG txspub9098 / res2
# CONSTANT txsprive9098
*estimation et sauvegarde de la série des résidus sous le nom res2

LINREG res1
# CONSTANT res2
*régression de la série de résidus res1 en fonction de celle des
*résidus res2

DISPLAY '*******************************************************'
DISPLAY 'Problème n°3 : test du degré de mobilité des capitaux'
DISPLAY 'et déficit commercial'
DISPLAY '*******************************************************'

DISPLAY 'QUESTION 1'

LINREG dc7098
# CONSTANT txs7098


DISPLAY 'QUESTION 2'

LINREG dc7098
# CONSTANT  txsprive7098 txspub7098
RESTRICT(CREATE) 1
# 2 3
# 1 -1 0

OPEN COPY H:\RATS\donnees_chap2.xls
COPY(FORMAT=XLS,ORG=COLS,DATES) / txs7098 txi7098 txs7098 esti7098
*sauvegarde les séries au format .xls dans le fichier donnees_chap2
*afin de réaliser les graphiques sous excel