// section 2.2
function cvloi(n,p,N)
X=(sqrt(n/(p*(1-p))))*(grand(1,N,"bin",n,p)/n-p);
xbasc()
histplot(30,X,5)
x=[-5:.01:5]
plot2d(x,(exp(-x.^2/2))/sqrt(2*%pi),2)
legends(['Histogramme','Densité gaussienne'],[5,2],1)
xtitle('Convergence en loi pour des v.a. de Bernoulli')


// section 2.3
function lfgn(n)
X=2*rand(1,n,'n')+1
si=zeros(1,n)
for i=2:n
  si=st_deviation(X(1:i))
end
xbasc();
y=[1:n]
xb=cumsum(X)./y;
plot2d(y,xb,5)
plot2d(y,xb+1.96*si./sqrt(y),2)
plot2d(y,xb-1.96*si./sqrt(y),2)
plot2d([1 n],[1 1],3)
legends(['Moyenne empirique','Valeur théorique','Bornes de l''IC à 95%'],[5,3,2],1)
xtitle('Intervalles de confiance')


// section 3.1
function medps(n)
X=grand(1,n,"exp",1);
med=zeros(1,n);
for i=1:n
  med(i)=median(X(1:i))
end
xbasc();
plot2d([1:n],med,5)
plot2d([1 n],[log(2) log(2)],2)
legends(['Médiane empirique','Médiane théorique'],[5,2],1)
xtitle('Convergence ps de la médiane')


function medloi(n,N)
med=zeros(1,N)
for i=1:N
   med(i)=median(grand(1,n,"exp",1))
end
histplot(30,sqrt(n)*(med-log(2)),5)
x=[-5:.01:5]
plot2d(x,(exp(-x.^2/2))/sqrt(2*%pi),2)
legends(['Histogramme','Densité gaussienne'],[5,2],1)
xtitle('Convergence en loi la médiane empirique')


// section 3.2
function minps(n)
X=rand(1,n);
minim=zeros(1,n);
minim(1)=X(1);
for i=2:n
  minim(i)=min(minim(i-1),X(i))
end
xbasc();
plot2d([1:n],minim,5)
plot2d([1 n],[0 0],2)
legends(['Minimum empirique','Minimum théorique'],[5,2],1)
xtitle('Convergence ps du minimum de v.a. uniformes')


function minloi(n,N)
minim=zeros(1,N)
for i=1:N
   minim(i)=min(rand(1,n))
end
histplot(30,n*minim,5)
x=[0:.01:5]
plot2d(x,exp(-x),2)
legends(['Histogramme','Densité loi expo 1'],[5,2],1)
xtitle('Convergence en loi du minimum de v.a. uniformes')


//section 3.3
function quantemp(q,d,n)
X=grand(1,n,"chi",d)
X=-sort(-X)
disp('Quantile empirique : '+string(X(int(q*n))))